x11-libs/goffice: Version bump to 0.10.48

Package-Manager: Portage-3.0.6, Repoman-3.0.1
Signed-off-by: David Seifert <soap@gentoo.org>

x11-libs/goffice/Manifest

@@ -1 +1,2 @@
 DIST goffice-0.10.47.tar.xz 2400616 BLAKE2B 16a92b3aa5c6e53cb0fe3f51d3ce03a9df6a18f50c0d6890da6ca2529f9e90e3ba30bef63b3c840697d229f58a723957731f985bf02ba80ec4d63bc93d6b7c1a SHA512 0db26fbd049893ee9274ee492e1dc3f10ae789cf99cc0b9dda3f1c2f106423e4679cc56515eb08bbf752aaf48492212777eee08d43a9fefb0b22048e883f5a76
+DIST goffice-0.10.48.tar.xz 2413400 BLAKE2B dce2a4fe1aa7399ce28974383f382f7a46a4b84ee2e8106ad72cf9631926767d59784ce14b2cfec9abea2367b026f83d4bf488464ca87af961f66f6e0243036b SHA512 90ce49c666a164205f8f78dca9fa40c81ddf0312b1b7f76808b8813d168868b5ce46c307fd5405a1314b0a475a4e52e95ab379b2dc751c1626e085ecf846d0f3

x11-libs/goffice/goffice-0.10.48.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org libtool
+
+DESCRIPTION="A library of document-centric objects and utilities"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/goffice/"
+
+LICENSE="GPL-2"
+SLOT="0.10"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+IUSE="+introspection"
+
+# FIXME: add lasem to tree
+RDEPEND="
+	>=app-text/libspectre-0.2.6:=
+	>=dev-libs/glib-2.40.0:2
+	>=dev-libs/libxml2-2.4.12:2
+	dev-libs/libxslt
+	>=gnome-base/librsvg-2.22:2
+	>=gnome-extra/libgsf-1.14.24:=[introspection?]
+	>=x11-libs/cairo-1.10:=[svg]
+	>=x11-libs/gdk-pixbuf-2.22:2
+	>=x11-libs/gtk+-3.20:3
+	>=x11-libs/pango-1.24:=
+	x11-libs/libXext:=
+	x11-libs/libXrender:=
+	introspection? (
+		>=dev-libs/gobject-introspection-1:=
+		>=gnome-extra/libgsf-1.14.23:=
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.12
+	>=dev-util/intltool-0.35
+	virtual/perl-Compress-Raw-Zlib
+	virtual/perl-Getopt-Long
+	virtual/perl-IO-Compress
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--disable-gtk-doc \
+		--disable-maintainer-mode \
+		--without-lasem \
+		--with-gtk \
+		--with-config-backend=gsettings \
+		$(use_enable introspection)
+}
+
+src_install() {
+	default
+	dodoc MAINTAINERS
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
+}