dev-python/PyQt6-WebEngine: add 6.8.0_pre2411020930

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

dev-python/PyQt6-WebEngine/Manifest

@@ -1 +1,2 @@
 DIST PyQt6_WebEngine-6.7.0.tar.gz 32593 BLAKE2B 6c14323b440a83f6fed9f1f77f20b350f00255dfedfbc328a5ee638760d20958d8864eb3c590248acd5c69152c537993a95e66d1f76b28349561c8223dfc2a85 SHA512 8298aecc43e420c4fa912802fd66ee95fd71156d9a6d1f1a499ffcc2d0d45a8c3e3c170f911acfc8f094d2e434567b5143b145ce40413ee75c9a9e4420341c0c
+DIST PyQt6_WebEngine-6.8.0.dev2411020930.tar.gz 34309 BLAKE2B e881ea3b91b1ebccf7b93df3c0dc645e2505223948478b2e4a6399fc380e08460d8ce3cd42857adaa68a8323439257891028b43a6334f0ef2cf4e3b6e13064dc SHA512 5acd6f8712bf1964cd15ee3696bccf37aca00a3c6428df03500a678e1f7f88b1c02015fb1f7b698c4bb9db24868b99df878cf3187a14addb7b7f66354a1960c5

dev-python/PyQt6-WebEngine/PyQt6-WebEngine-6.8.0_pre2411020930.ebuild

@@ -0,0 +1,74 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=sip
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/_}
+PYTHON_COMPAT=( python3_{10..13} )
+inherit distutils-r1 flag-o-matic multiprocessing pypi qmake-utils
+
+QT_PV=$(ver_cut 1-2):6
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/"
+
+# TODO: drop this and uncomment 'pypi' on a proper bump
+MY_P=${PN/-/_}-$(ver_cut 1-3).dev$(ver_cut 5)
+SRC_URI="https://www.riverbankcomputing.com/pypi/packages/PyQt6-WebEngine/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="debug quick +widgets"
+
+RDEPEND="
+	>=dev-python/PyQt6-${QT_PV%:*}[gui,ssl,${PYTHON_USEDEP}]
+	>=dev-qt/qtbase-${QT_PV}[gui,widgets?]
+	>=dev-qt/qtwebengine-${QT_PV}[widgets]
+	quick? (
+		dev-python/PyQt6[qml]
+		>=dev-qt/qtwebengine-${QT_PV}[qml]
+	)
+	widgets? ( dev-python/PyQt6[network,printsupport,webchannel,widgets] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-python/PyQt-builder-1.11[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.8[${PYTHON_USEDEP}]
+	>=dev-qt/qtbase-${QT_PV}
+"
+
+src_prepare() {
+	default
+
+	# hack: PyQt-builder runs qmake without our arguments and calls g++
+	# or clang++ depending on what qtbase was built with, not used for
+	# building but fails with -native-symlinks
+	mkdir "${T}"/cxx || die
+	local cxx
+	! cxx=$(type -P "${CHOST}"-g++) || ln -s -- "${cxx}" "${T}"/cxx/g++ || die
+	! cxx=$(type -P "${CHOST}"-clang++) || ln -s -- "${cxx}" "${T}"/cxx/clang++ || die
+	PATH=${T}/cxx:${PATH}
+}
+
+python_configure_all() {
+	append-cxxflags -std=c++17 # for old gcc / clang that use <17 (bug #892331)
+	append-cxxflags ${CPPFLAGS} # respect CPPFLAGS notably for DISTUTILS_EXT=1
+
+	DISTUTILS_ARGS=(
+		--jobs="$(makeopts_jobs)"
+		--qmake="$(qt6_get_bindir)"/qmake
+		--qmake-setting="$(qt6_get_qmake_args)"
+		--verbose
+
+		--enable=QtWebEngineCore
+		$(usex quick --{enable,disable}=QtWebEngineQuick)
+		$(usex widgets --{enable,disable}=QtWebEngineWidgets)
+
+		$(usev debug '--debug --qml-debug --tracing')
+	)
+}