mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
www-client/falkon: 24.08.1 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST falkon-24.05.2.tar.xz 2584984 BLAKE2B 5743e689281cd38e07f352499a8ef96ffe3300f702721dbd3493753b1346af6a4a837b0034366136b7b1bfb4566a62ae9b9050c1e67733d3b6d1b3713d915c63 SHA512 b3d6b2f13431871d1f6202eeeafac9b821c5b9d140eb635b9c4bcfb3f2cc785d0fcabfcd983f25cfcdc76fd20d9f90bf46ed766db42228eaad34ad524a228a3b
|
||||
DIST falkon-24.08.0.tar.xz 2635528 BLAKE2B 994ebe555c41f7b6552c0ea4cf921840dc791d50f1d6cd6cefb79fac74fb747e4de57830e412d29c3138bfbd9b41bdaeda10a62838d2dbd5a306d029f50cd953 SHA512 b136a8e4a8c63da2d7cf45a1be3cf00df48f19ee31845c25d5464aa5e7ec51315268304707e7a147f8ca899100d497b5ba42d4586383175e96401af26df440df
|
||||
DIST falkon-24.08.1.tar.xz 2635616 BLAKE2B 7dd7372dc79022097b177b77bd22d76f5d5091e484f482d036869fccd93701e618601ddb7860f57f9c923fb6de5dd80a84c8de7d19b30b5bcaf06466c8921c57 SHA512 be2adc32aaa271a60c5e5e253b7f23807a41c489817e5cbbc454af104652d2262c63f175a002f0643cfd13a437f3569d6e9752522130b4f18ba006390d97c40d
|
||||
|
||||
@@ -0,0 +1,83 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_TEST="true"
|
||||
KFMIN=6.5.0
|
||||
QTMIN=6.7.2
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
inherit ecm gear.kde.org python-single-r1
|
||||
|
||||
DESCRIPTION="Cross-platform web browser using QtWebEngine"
|
||||
HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
IUSE="dbus kde python +X"
|
||||
|
||||
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
RESTRICT="test" # bug 653046
|
||||
|
||||
COMMON_DEPEND="
|
||||
dev-libs/openssl:0=
|
||||
>=dev-qt/qt5compat-${QTMIN}:6
|
||||
>=dev-qt/qtbase-${QTMIN}:6[dbus?,gui,network,sql,sqlite,ssl,widgets]
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
|
||||
>=dev-qt/qtwebchannel-${QTMIN}:6
|
||||
>=dev-qt/qtwebengine-${QTMIN}:6=[widgets]
|
||||
>=kde-frameworks/karchive-${KFMIN}:6
|
||||
virtual/libintl
|
||||
kde? (
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kcrash-${KFMIN}:6
|
||||
>=kde-frameworks/kio-${KFMIN}:6
|
||||
>=kde-frameworks/kjobwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/kwallet-${KFMIN}:6
|
||||
>=kde-frameworks/purpose-${KFMIN}:6
|
||||
)
|
||||
python? (
|
||||
${PYTHON_DEPS}
|
||||
$(python_gen_cond_dep "
|
||||
>=dev-python/pyside6-${QTMIN}[designer,gui,positioning,webengine,widgets,\${PYTHON_USEDEP}] \
|
||||
>=dev-python/shiboken6-${QTMIN}[\${PYTHON_USEDEP}]
|
||||
")
|
||||
)
|
||||
X? (
|
||||
x11-libs/libxcb:=
|
||||
x11-libs/xcb-util
|
||||
)
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=dev-qt/qtbase-${QTMIN}:6[concurrent]
|
||||
"
|
||||
if [[ ${KDE_BUILD_TYPE} != live ]]; then
|
||||
DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:6"
|
||||
fi
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
>=dev-qt/qtsvg-${QTMIN}:6
|
||||
"
|
||||
BDEPEND=">=dev-qt/qttools-${QTMIN}:6[linguist]"
|
||||
|
||||
pkg_setup() {
|
||||
use python && python-single-r1_pkg_setup
|
||||
ecm_pkg_setup
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_KEYRING=OFF
|
||||
-DDISABLE_DBUS=$(usex !dbus)
|
||||
$(cmake_use_find_package kde KF6Wallet)
|
||||
$(cmake_use_find_package kde KF6KIO)
|
||||
-DBUILD_PYTHON_SUPPORT=$(usex python)
|
||||
-DNO_X11=$(usex !X)
|
||||
)
|
||||
use python && mycmakeargs+=(
|
||||
-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
|
||||
-DPython3_INCLUDE_DIR=$(python_get_includedir)
|
||||
-DPython3_LIBRARY=$(python_get_library_path)
|
||||
)
|
||||
ecm_src_configure
|
||||
}
|
||||
Reference in New Issue
Block a user