dev-libs/sway: version bump to 0.9.

Closes: https://github.com/gentoo/gentoo/pull/2041

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

dev-libs/sway/Manifest

@@ -1 +1,2 @@
 DIST sway-0.8.tar.gz 11002027 SHA256 eb229098f87b242ab9259d3057e7e9a8cad610659546988b73ffa866ec62f7fd SHA512 922b36cb484d2dbfd2b9309c5a65debc36e2a2304f9fbd980eba4c19ca1147d48fa01cf9f64e55cff2fd7ef6f7efaf87ef8145bda5b5ca76e2b1bded60e4aa64 WHIRLPOOL 5a70997bcf68141f6fba13eaa45655eee168d2bbe5e45329a49e95567a07476afe4a63d5afb3ef59511207ac689b6dba3633dba2e08dfa192761ae5003075f01
+DIST sway-0.9.tar.gz 11010131 SHA256 dc98fe5abd084dbf059fdf19b5b40e44b5c7ac75a5b704b47a6b53c9f489f42d SHA512 546af976379f50314567472766fe801dc15e84057bc1bd4d8b9b8c02ddc897ce3ece264a429bcc7c44f6fa2f7a58ed65f92d5a194951297c5d37dbb8085658cf WHIRLPOOL de3bbc9139d851088018a57a1668edbe585701960e705881f36e9c6077475fd80d40a44a37bb2ddbe74378dbc169aa947e08da975208e2a5904722f6c81b5af3

dev-libs/sway/sway-0.9.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils cmake-utils
+
+DESCRIPTION="i3-compatible Wayland window manager"
+HOMEPAGE="http://swaywm.org/"
+
+SRC_URI="https://github.com/SirCmpwn/sway/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+swaybg +swaybar +swaymsg swaygrab swaylock +gdk-pixbuf zsh-completion wallpapers systemd"
+
+RDEPEND=">=dev-libs/wlc-0.0.5[systemd=]
+	dev-libs/json-c
+	dev-libs/libpcre
+	dev-libs/libinput
+	x11-libs/libxkbcommon
+	dev-libs/wayland
+	x11-libs/pango
+	x11-libs/cairo
+	swaylock? ( virtual/pam )
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf[jpeg] )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	app-text/asciidoc"
+
+src_prepare() {
+	default
+
+	# remove bad CFLAGS that upstream is trying to add
+	sed -i -e '/FLAGS.*-Werror/d' -e '/FLAGS.*-g/d' CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Denable-swaybar=$(usex swaybar)
+		-Denable-swaybg=$(usex swaybg)
+		-Denable-swaygrab=$(usex swaygrab)
+		-Denable-swaylock=$(usex swaylock)
+		-Denable-swaymsg=$(usex swaymsg)
+
+		-Ddefault-wallpaper=$(usex wallpapers)
+
+		-Denable-gdk-pixbuf=$(usex gdk-pixbuf)
+		-Dzsh-completions=$(usex zsh-completion)
+
+		-DCMAKE_INSTALL_SYSCONFDIR="/etc"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use !systemd && fperms u+s /usr/bin/sway
+}
+
+pkg_postinst() {
+	if use swaygrab; then
+		optfeature "swaygrab screenshot support" media-gfx/imagemagick[png]
+		optfeature "swaygrab video capture support" virtual/ffmpeg
+	fi
+}