games-action/bzflag: add 2.4.28

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

games-action/bzflag/Manifest

@@ -1 +1,2 @@
 DIST bzflag-2.4.26.tar.bz2 14107130 BLAKE2B f7fe50910f49f82c7316d19f7b5dba2de26cbe2b928c29158b725be6424d5a55423e2d390c8c0d96cc40ff90191c6d1ab0d378014381ef44f6fcd534c06fc9a9 SHA512 1ca039d840440098ea788009ad94fccec20710f621967843b5f95dc4ee054cb1d5d9b94326687008cf7a11020889225ffe9001aac1c7c4339f6761961f422a78
+DIST bzflag-2.4.28.tar.bz2 13993838 BLAKE2B 9a18ae8adc5f089035cace94a8b8accf2661aa0cb1c15ebabe35267733db0ee8e290a73496d62d6ecf565526e70827952721cd9855f704dc010808244862f0b5 SHA512 6ddb32b0e7a6d131e45d50283ad8afac96c792f649843f7f4a1b4716e5c0f02f9efcbe6f919b710c3bc730c761fe07be48ea9a00612431ac6762c44ec9794ef1

games-action/bzflag/bzflag-2.4.28.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop
+
+DESCRIPTION="3D tank combat simulator game"
+HOMEPAGE="https://www.bzflag.org/"
+SRC_URI="https://download.bzflag.org/bzflag/source/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dedicated upnp"
+
+RDEPEND="
+	net-dns/c-ares
+	>=net-misc/curl-7.15.0
+	sys-libs/ncurses:0
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl2[joystick,sound,video]
+		media-libs/glew:=
+		virtual/glu
+		virtual/opengl )
+	upnp? ( net-libs/miniupnpc )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.4.12-configure.patch
+	"${FILESDIR}"/${PN}-2.4.12-tinfo.patch
+)
+
+DOCS=( AUTHORS ChangeLog DEVINFO PORTING README README.Linux )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable upnp UPnP)
+		--libdir="${EPREFIX}"/usr/$(get_libdir)/${PN}
+	)
+
+	if use dedicated ; then
+		ewarn
+		ewarn "You are building a server-only copy of BZFlag"
+		ewarn
+		myconf+=( --disable-client --without-SDL )
+	else
+		myconf=( --with-SDL=2 )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	if ! use dedicated ; then
+		newicon data/bzflag-48x48.png ${PN}.png
+		make_desktop_entry ${PN} "BZFlag"
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}