app-misc/solaar: Version bump to 1.0.1, Python 3.7 and EAPI 7

Bug: https://bugs.gentoo.org/691208
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Chris Mayo <aklhfex@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/12679
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

app-misc/solaar/Manifest

@@ -1 +1,2 @@
 DIST solaar-0.9.2.tar.gz 864509 BLAKE2B 57c58d203d8d1ae390eaaa1cfc963cfcc9523de8d7edcb482f30c66bcaaceebc7c514cf0fcffb1b20ca5cc3bc869c94cb61bcddff44debba9307ec3b1c0e1def SHA512 13f469df753cc8fab55f5259ccc3e62b6e44471d277d240cd56ce0580144d2b1f95d731268176648663dd15e5607bfb512f477362f4f100aa0a653b001dfe04b
+DIST solaar-1.0.1.tar.gz 1195660 BLAKE2B e6cd89b5735e125dd438255a8961b1d5d38feb515c5097efec0403d99b9db6e29c439c13e279fcffe69cb314bf2650a7a11770830fdf1e971ade27ce8331aed2 SHA512 e0b2bbfd97d9650d94f1a4b47e4e70f09c75f684e7e1d3e67d2cf6dd197109084e941b98333e173fb205d5c9464dd07e17390d9c2d5b46393fee2efdb20429ac

app-misc/solaar/solaar-1.0.1.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1 linux-info udev xdg
+
+DESCRIPTION="A Linux device manager for Logitech's Unifying Receiver peripherals"
+HOMEPAGE="https://pwr-solaar.github.io/Solaar/"
+SRC_URI="https://github.com/pwr-Solaar/Solaar/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc"
+
+RDEPEND="
+	acct-group/plugdev
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]"
+
+S=${WORKDIR}/Solaar-${PV}
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+python_prepare_all() {
+	# don't autostart (bug #494608)
+	sed -i '/yield autostart_path/d' setup.py || die
+
+	# grant plugdev group rw access
+	sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	udev_dorules rules.d/*.rules
+
+	dodoc docs/devices.md
+	if use doc; then
+		dodoc -r docs/*
+	fi
+}