gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

media-sound/sox: add 14.4.5.1

Browse Source 
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/95
Merges: https://codeberg.org/gentoo/gentoo/pulls/95
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Alfred Wingate
2026-02-19 14:53:32 +02:00
committed by Sam James
parent 87cc3643d4
commit a9f6520a29
2 changed files with 103 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
media-sound/sox/Manifest
View File

@@ -1,5 +1,6 @@
DIST sox-14.4.2_p20210509-patchset.tar.xz 3560 BLAKE2B 8f575dbff121d749c83c6074dadeb92475472f36ad5b9c389e1591b60cff853167c22f7c059731fa5b78c497817bcae6be93ace21bfe605faf2445301a0fe2af SHA512 4b57689bc85ac7664693c6344fd17c7fc7991e04d5e6628c2455c8e541ecfec073690d4dc23a909474ba93fd24cd877aa77f1e7fcc5b52773daa794689212bb8
DIST sox-14.4.2_p20210509.zip 942551 BLAKE2B 2ddd229faacb9190fe18052b1c02da40d4c3f24fc73dd08b28ac99bef267cb05f8bcbf64e0c397c391b3be2467667783ed94f6c60798af069567e1c237ec9ccd SHA512 4868f9b77141b7e2caf2571ceb68a48bd744732e72f63ed787f8e0b9fe39b77de4e998b32d99c2500e10b017a1fd1a3379f4f9f8b67db6093b85d02cb3447934
DIST sox_ng-14.4.4.1.tar.gz 1617773 BLAKE2B 23faae4872c5aa18ea5240fd8613275369aed21ad9114b9cb082023f714dc4cfd404b3fe64db307e9e1d4cc6c2499e55a3155c7d353a8102b07790045029e97f SHA512 4498036622a7ec0faa7ff7be2ad5d582afee70660b9d8b19e41305cc87330bfe6abcb218ff9a26de3e1a0fdf64c45062b8ee431a18261c8adc7e42d82c3b2f4f
DIST sox_ng-14.4.5.1.tar.gz 1596744 BLAKE2B 224e117fa319436c24eb7477829f2530ec3abe4777cc9cee78f47f67448e501df16b2c247b751565a636a74de0e33547fbef988849e8892f0eff5fcc89a1f160 SHA512 cf98a8c6b81e0fa4d72716005f9e3d48d2a547ea443edc0996c9cbfc5fff32c2cb5d1ebb6fe8e429c7600e6936533a92389b599bd572b19d12d49691afa4893e
DIST sox_ng-14.6.0.4.tar.gz 1791426 BLAKE2B 5c17ddb86715f56f5c6df55df855acbc7c636b70d39ec8dde149079bc45438d6791000b902a0a96b88d0fafa939425c0fc576d484733efc93c0c31215f90d8d1 SHA512 53ed5f2037cf392c16121ff4584345a7d8b6fdb51195b6ea0e2ebb99d009b96ae6d5a4522320a088d99e97716935bee1d59d20f9c68608dca4cd91ff3fdd625a
DIST sox_ng-14.7.0.9.tar.gz 2086694 BLAKE2B 8ca815c1380646fbc83fb9ce20b1e7f67dff2bf7d53c1c009881134f3a6384d08d46f987fe593f8925e6f1804f7f524e88b5d9b1f27a2021eb8ccac56fea545a SHA512 dacda7e2d434a861eac870f92a29182a8b1b10a95f0fe194457c0dffe67773cdc7e5649a9d76968fe3092db9afce9e9643fdd68bbfca020560a8cf391b215155

102
media-sound/sox/sox-14.4.5.1.ebuild Normal file
View File

@@ -0,0 +1,102 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools flag-o-matic
MY_PN="sox_ng"
MY_PV="${PV/_rc/-rc}"
MY_P="${MY_PN}-${MY_PV}"
DESCRIPTION="The swiss army knife of sound processing programs"
HOMEPAGE="https://codeberg.org/sox_ng/sox_ng"
SRC_URI="https://codeberg.org/sox_ng/sox_ng/releases/download/${MY_P}/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
# https://codeberg.org/sox_ng/sox_ng/wiki/Copyright
LICENSE="GPL-2"
SLOT="0/3" # SHLIB_VERSION in configure.ac
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="alsa amr ao encode flac id3tag ladspa mad ogg openmp oss opus png pulseaudio sndfile sndio twolame wavpack"
RDEPEND="
dev-libs/libltdl:0=
>=media-sound/gsm-1.0.12-r1
sys-apps/file
alsa? ( media-libs/alsa-lib )
amr? ( media-libs/opencore-amr )
ao? ( media-libs/libao:= )
encode? ( >=media-sound/lame-3.98.4 )
flac? ( >=media-libs/flac-1.1.3:= )
id3tag? ( media-libs/libid3tag:= )
ladspa? ( media-libs/ladspa-sdk )
mad? ( media-libs/libmad )
ogg? (
media-libs/libogg
media-libs/libvorbis
)
opus? (
media-libs/opus
media-libs/opusfile
)
png? (
media-libs/libpng:0=
virtual/zlib:=
)
pulseaudio? ( media-libs/libpulse )
sndfile? ( >=media-libs/libsndfile-1.0.11 )
sndio? ( media-sound/sndio:= )
twolame? ( media-sound/twolame )
wavpack? ( media-sound/wavpack )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
"
DOCS=( AUTHORS ChangeLog )
src_prepare() {
default
eautoreconf
}
src_configure() {
# Workaround for LLD (bug #914867)
# https://codeberg.org/sox_ng/sox_ng/issues/69
append-ldflags $(test-flags-CCLD -Wl,--undefined-version)
local myeconfargs=(
$(use_with alsa)
$(use_with amr amrnb)
$(use_with amr amrwb)
$(use_with ao)
$(use_with encode lame)
$(use_with flac)
$(use_with id3tag)
$(use_with ladspa ladspa dyn)
$(use_with mad)
--with-magic
$(use_enable openmp)
$(use_with ogg oggvorbis)
$(use_with oss)
$(use_with opus)
$(use_with png)
$(use_with pulseaudio)
$(use_with sndfile)
$(use_with sndio)
$(use_with twolame)
$(use_with wavpack)
--enable-replace # bug #960558
--disable-debug # user cflags
--with-distro="Gentoo"
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${ED}" \( -type f -or -type l \) -name '*.la' -delete || die
}