media-libs/sdl_audiolib: add 0_p20230225

Not much different than the previous snapshot, but given had
no commits in >3 years may as well update it to latest and
update the cmake version while here.

Closes: https://bugs.gentoo.org/964533
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
Ionen Wolkens
2026-11-02 04:57:08 -05:00
parent 185564b2a2
commit a9bfc503c9
3 changed files with 91 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST sdl_audiolib-0_p20220622.tar.gz 1138752 BLAKE2B 01e565506b29e922f3eb5ff2705a0614e53c6afd43526d781eb83d86f54dab6692689de51d618e07779fe8c97ee2cfbe3de744f29c1798e3f10205141dcb28ea SHA512 ec6267665fb1a98fcfb91a40ebbd86f7bb14e9fed36509a903ba5408d0f4b8672b19421943de6a4b3d2d0b187f9531dae4b7c9f766ee07f9c1aefa08ab6a51e3
DIST sdl_audiolib-0_p20230225.tar.gz 1140197 BLAKE2B bd24494bab94c9eaefc17f88b6e6a43b49e7c857939d67cbcb8893a9a681c7f8b528453bec5290c696e792de757265ff4e8b91e1be87cc1eba67ca9fc948b76e SHA512 ea9f393f933520bb761c1bef13e3ecb4d7ad525917211fcab740d55223e84e4fd69457ff7b784f17a2c4d4e11cf1779fad30d0db8b6474ec79ebeeb0343c56ed
@@ -0,0 +1,6 @@
https://bugs.gentoo.org/964533
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1 +1 @@
-cmake_minimum_required(VERSION 3.8)
+cmake_minimum_required(VERSION 3.8...4.3)
@@ -0,0 +1,84 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
SDLAL_COMMIT=b2df2dfeddc692caa01fd1e1769f59b285912b87
DESCRIPTION="Audio decoding, resampling and mixing library for SDL"
HOMEPAGE="https://github.com/realnc/SDL_audiolib/"
SRC_URI="
https://github.com/realnc/SDL_audiolib/archive/${SDLAL_COMMIT}.tar.gz
-> ${P}.tar.gz
"
S=${WORKDIR}/${PN/sdl/SDL}-${SDLAL_COMMIT}
LICENSE="LGPL-3+ BSD-2 || ( MIT Unlicense )"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="
doc flac fluidsynth libsamplerate modplug mpg123 musepack openmpt
opus sndfile soxr vorbis wildmidi
"
RDEPEND="
dev-libs/libfmt:=
media-libs/libsdl2[sound]
flac? ( media-libs/flac:= )
fluidsynth? ( media-sound/fluidsynth:= )
libsamplerate? ( media-libs/libsamplerate )
modplug? ( media-libs/libmodplug )
mpg123? ( media-sound/mpg123-base )
musepack? ( media-sound/musepack-tools )
openmpt? ( media-libs/libopenmpt )
opus? ( media-libs/opusfile[float] )
sndfile? ( media-libs/libsndfile )
soxr? ( media-libs/soxr )
vorbis? ( media-libs/libvorbis )
wildmidi? ( media-sound/wildmidi )
"
DEPEND="${RDEPEND}"
BDEPEND="
doc? ( app-text/doxygen )
"
PATCHES=(
"${FILESDIR}"/${PN}-0_p20230225-cmake4.patch
)
src_configure() {
local mycmakeargs=(
-DUSE_DEC_ADLMIDI=no
-DUSE_DEC_BASSMIDI=no
-DUSE_DEC_FLAC=$(usex flac)
-DUSE_DEC_FLUIDSYNTH=$(usex fluidsynth)
-DUSE_DEC_LIBOPUSFILE=$(usex opus)
-DUSE_DEC_LIBVORBIS=$(usex vorbis)
-DUSE_DEC_MODPLUG=$(usex modplug)
-DUSE_DEC_MPG123=$(usex mpg123)
-DUSE_DEC_MUSEPACK=$(usex musepack)
-DUSE_DEC_OPENMPT=$(usex openmpt)
-DUSE_DEC_SNDFILE=$(usex sndfile)
-DUSE_DEC_WILDMIDI=$(usex wildmidi)
-DUSE_DEC_XMP=no
-DUSE_RESAMP_SOXR=$(usex soxr)
-DUSE_RESAMP_SRC=$(usex libsamplerate)
-DWITH_SYSTEM_FMTLIB=yes
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
use !doc || doxygen "${BUILD_DIR}"/Doxyfile || die
}
src_install() {
cmake_src_install
use doc && dodoc -r "${BUILD_DIR}"/doc/html
}