mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-22 10:57:07 -08:00
dev-libs/libgit2: Bump to 1.5.1
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST libgit2-1.5.0.tar.gz 5893437 BLAKE2B 4108de0e8fc6a02e4172f47cb69cdfe8c85a0a72235432ca58b02d94e0bcb8390caf0c710060772551cc3a392291778ae14b561256c6d88058d0ae5a277f2fbf SHA512 7a32b27cd32bd03ce7be6c127317f82a4ac6f16615c3234699676781f4858d057edb0410b2fe36fd2e634b00748a8b0be17f23809e09a7602ba48185134300f7
|
||||
DIST libgit2-1.5.1.tar.gz 5895483 BLAKE2B 4df80216523f4065e46c1ce99fd0747d2f8516571691c8c2b5638e32c805f5ce08d3add769e6d5ce29ac69b35419db82ce56c6b3019e70573c4ad63aca2e440d SHA512 04cf389e30cd9fb787704e3c8997acaaeea5c13e1e2f9eaf9f5598d35c2e85f3cf04b47312cae9e7278236ecb089c2d33addd852e38d3c7d2daa87929b077f39
|
||||
|
||||
@@ -0,0 +1,76 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{9..11} )
|
||||
inherit cmake python-any-r1
|
||||
|
||||
DESCRIPTION="A linkable library for Git"
|
||||
HOMEPAGE="https://libgit2.org/"
|
||||
SRC_URI="
|
||||
https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
|
||||
"
|
||||
S=${WORKDIR}/${P/_/-}
|
||||
|
||||
LICENSE="GPL-2-with-linking-exception"
|
||||
SLOT="0/$(ver_cut 1-2)"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-macos"
|
||||
IUSE="examples gssapi +ssh test +threads trace"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libpcre2:=
|
||||
net-libs/http-parser:=
|
||||
sys-libs/zlib
|
||||
dev-libs/openssl:0=
|
||||
gssapi? ( virtual/krb5 )
|
||||
ssh? ( net-libs/libssh2 )
|
||||
"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
"
|
||||
BDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
cmake_src_prepare
|
||||
# relying on forked http-parser to support some obscure URI form
|
||||
sed -i -e '/empty_port/s:test:_&:' \
|
||||
tests/libgit2/network/url/parse.c || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_TESTS=$(usex test)
|
||||
-DUSE_SSH=$(usex ssh)
|
||||
-DUSE_GSSAPI=$(usex gssapi ON OFF)
|
||||
-DUSE_HTTP_PARSER=system
|
||||
-DREGEX_BACKEND=pcre2
|
||||
)
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
if [[ ${EUID} -eq 0 ]] ; then
|
||||
# repo::iterator::fs_preserves_error fails if run as root
|
||||
# since root can still access dirs with 0000 perms
|
||||
ewarn "Skipping tests: non-root privileges are required for all tests to pass"
|
||||
else
|
||||
local TEST_VERBOSE=1
|
||||
cmake_src_test -R offline
|
||||
fi
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake_src_install
|
||||
dodoc docs/*.{md,txt}
|
||||
|
||||
if use examples ; then
|
||||
find examples -name '.gitignore' -delete || die
|
||||
dodoc -r examples
|
||||
docompress -x /usr/share/doc/${PF}/examples
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user