mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-22 10:57:07 -08:00
media-gfx/inkscape: Version bump (v1.0)
Package-Manager: Portage-2.3.89, Repoman-2.3.20 Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST inkscape-0.92.4.tar.bz2 31929728 BLAKE2B 892bf4ed913019b27a9b8897e3ae32c44152163ded0eb345d59915ffdc9818d29f210de3294ef1b05601141185b5e3b10779778551b860f31e7df5c659492c77 SHA512 b9034605a79cd8aea808edf42e284819951ae1ea67778f0922f4c10224e94aca6c844acbc2294625773f0a7047d4e32ccdada876238a792a2c17db172c88e120
|
||||
DIST inkscape-1.0_rc1.tar.xz 31984596 BLAKE2B 7e4a3618522c7bc9bedba8bb2a846e1cbf40e23868f04548e67fa41b9f8f1e8f696af386c0698a43ae6f7033937e1a3d4e772518162f712468b614a5b4d3b4ad SHA512 13e14a6dad1e89e6edf7c0197c43506d127b2e5136a2d8d931ad5ea0671b65b3feed5baf2f631b1a4b8095f285c19ffe5170904c9ce5e3e484d00ca2f0800b89
|
||||
DIST inkscape-INKSCAPE_1_0.tar.gz 64306274 BLAKE2B 8bc4e2d156fad99b2b2a700bde29372dd56db6a1a9a8e825d46d214bbd18a1d29365510c16d51dbb2cad88f88fb10232f1bab403da4900beaa72de5d0f8726df SHA512 214c04c7f1d23dd0d296f4262743b2a206fe3b3df7abdb4bc4a4604a7f0caab2d7970d04b5795f121417d0e015e2d42d14be0b67438d752a81c4ad079b486f06
|
||||
|
||||
@@ -0,0 +1,162 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{6,7,8} )
|
||||
PYTHON_REQ_USE="xml"
|
||||
|
||||
inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1
|
||||
|
||||
DESCRIPTION="SVG based generic vector-drawing program"
|
||||
HOMEPAGE="https://inkscape.org/"
|
||||
SRC_URI="https://gitlab.com/inkscape/inkscape/-/archive/${PN^^}_$(ver_rs 1-2 "_")/${PN}-${PN^^}_$(ver_rs 1-2 "_").tar.gz"
|
||||
|
||||
LICENSE="GPL-2 LGPL-2.1"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
|
||||
IUSE="cdr dbus dia exif graphicsmagick imagemagick inkjar jemalloc jpeg lcms nls
|
||||
openmp postscript spell static-libs svg2 visio wpg"
|
||||
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
||||
|
||||
BDEPEND="
|
||||
dev-util/glib-utils
|
||||
>=dev-util/intltool-0.40
|
||||
>=sys-devel/gettext-0.17
|
||||
virtual/pkgconfig
|
||||
"
|
||||
COMMON_DEPEND="${PYTHON_DEPS}
|
||||
>=app-text/poppler-0.57.0:=[cairo]
|
||||
>=dev-cpp/cairomm-1.12
|
||||
>=dev-cpp/glibmm-2.54.1
|
||||
dev-cpp/gtkmm:3.0
|
||||
>=dev-cpp/pangomm-2.40
|
||||
>=dev-libs/boehm-gc-7.1:=
|
||||
dev-libs/double-conversion:=
|
||||
>=dev-libs/glib-2.41
|
||||
>=dev-libs/libsigc++-2.8
|
||||
>=dev-libs/libxml2-2.7.4
|
||||
>=dev-libs/libxslt-1.1.25
|
||||
dev-libs/gdl:3
|
||||
dev-libs/popt
|
||||
media-gfx/potrace
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype:2
|
||||
media-libs/libpng:0=
|
||||
net-libs/libsoup
|
||||
sci-libs/gsl:=
|
||||
x11-libs/libX11
|
||||
>=x11-libs/pango-1.37.2
|
||||
x11-libs/gtk+:3
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/lxml[${PYTHON_MULTI_USEDEP}]
|
||||
media-gfx/scour[${PYTHON_MULTI_USEDEP}]
|
||||
')
|
||||
cdr? (
|
||||
app-text/libwpg:0.3
|
||||
dev-libs/librevenge
|
||||
media-libs/libcdr
|
||||
)
|
||||
dbus? ( dev-libs/dbus-glib )
|
||||
exif? ( media-libs/libexif )
|
||||
imagemagick? (
|
||||
!graphicsmagick? ( media-gfx/imagemagick:=[cxx] )
|
||||
graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
|
||||
)
|
||||
jemalloc? ( dev-libs/jemalloc )
|
||||
jpeg? ( virtual/jpeg:0 )
|
||||
lcms? ( media-libs/lcms:2 )
|
||||
spell? (
|
||||
app-text/aspell
|
||||
app-text/gtkspell:3
|
||||
)
|
||||
visio? (
|
||||
app-text/libwpg:0.3
|
||||
dev-libs/librevenge
|
||||
media-libs/libvisio
|
||||
)
|
||||
wpg? (
|
||||
app-text/libwpg:0.3
|
||||
dev-libs/librevenge
|
||||
)
|
||||
"
|
||||
# These only use executables provided by these packages
|
||||
# See share/extensions for more details. inkscape can tell you to
|
||||
# install these so we could of course just not depend on those and rely
|
||||
# on that.
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/numpy[${PYTHON_MULTI_USEDEP}]
|
||||
')
|
||||
dia? ( app-office/dia )
|
||||
postscript? ( app-text/ghostscript-gpl )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=dev-libs/boost-1.65
|
||||
"
|
||||
|
||||
RESTRICT="test"
|
||||
|
||||
S="${WORKDIR}"/${PN}-${PN^^}_$(ver_rs 1-2 "_")
|
||||
|
||||
pkg_pretend() {
|
||||
if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
|
||||
tc-has-openmp || die "Please switch to an openmp compatible compiler"
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
cmake_src_prepare
|
||||
sed -i "/install.*COPYING/d" CMakeScripts/ConfigCPack.cmake || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# aliasing unsafe wrt #310393
|
||||
append-flags -fno-strict-aliasing
|
||||
|
||||
local mycmakeargs=(
|
||||
# -DWITH_LPETOOL # Compile with LPE Tool and experimental LPEs enabled
|
||||
-DENABLE_POPPLER=ON
|
||||
-DENABLE_POPPLER_CAIRO=ON
|
||||
-DWITH_PROFILING=OFF
|
||||
-DWITH_LIBCDR=$(usex cdr)
|
||||
-DWITH_DBUS=$(usex dbus)
|
||||
-DWITH_IMAGE_MAGICK=$(usex imagemagick $(usex !graphicsmagick)) # requires ImageMagick 6, only IM must be enabled
|
||||
-DWITH_GRAPHICS_MAGICK=$(usex graphicsmagick $(usex imagemagick)) # both must be enabled to use GraphicsMagick
|
||||
-DWITH_JEMALLOC=$(usex jemalloc)
|
||||
-DENABLE_LCMS=$(usex lcms)
|
||||
-DWITH_OPENMP=$(usex openmp)
|
||||
-DBUILD_SHARED_LIBS=$(usex !static-libs)
|
||||
-DWITH_SVG2=$(usex svg2)
|
||||
-DWITH_LIBVISIO=$(usex visio)
|
||||
-DWITH_LIBWPG=$(usex wpg)
|
||||
)
|
||||
# We should also have,
|
||||
#
|
||||
# -DWITH_NLS=$(usex nls)
|
||||
#
|
||||
# in this list, but it's broken upstream at the moment:
|
||||
#
|
||||
# * https://bugs.gentoo.org/699658
|
||||
# * https://gitlab.com/inkscape/inkscape/issues/168
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake_src_install
|
||||
|
||||
find "${ED}" -type f -name "*.la" -delete || die
|
||||
|
||||
find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.bz2' -exec bzip2 -d {} \; || die
|
||||
|
||||
find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.gz' -exec gzip -d {} \; || die
|
||||
|
||||
# No extensions are present in beta1
|
||||
local extdir="${ED}"/usr/share/${PN}/extensions
|
||||
|
||||
if [[ -e "${extdir}" ]] && [[ -n $(find "${extdir}" -mindepth 1) ]]; then
|
||||
python_optimize "${ED}"/usr/share/${PN}/extensions
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user