app-arch/dpkg: add 1.22.14

Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
2025-01-19 00:42:00 +00:00
parent 31c1a238c6
commit a8be0e470d
2 changed files with 114 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST dpkg_1.21.15.tar.xz 5350148 BLAKE2B f26611db365266ef9f43484c20d3150889238b34b156cac26f0ae8ae9572e7e4a9839e08a0073a25c886cd2891fc6d84afc97262ae6992267b47fa6e86c03a33 SHA512 eb31db63dd454048c3b7539b539720ed71239303ca679df92b934e971914d63dd771da09149054048e24dde1f5627ee24d43dbd8782ca1dc28c4a2bd3ed8f26a
DIST dpkg_1.22.11.tar.xz 5697040 BLAKE2B 7bd7f90a8ae98ac7401bc2b8e7b0d2cc002a57bfdc5521d9049a995130011a3042ac6d24d6ecd5410e1db2c2e936eae5085a2af5fb11b0a73fd66bae33b33956 SHA512 8caeb52625e34109bbc3abf1b62792053f989e560b541ec9de85f3fe563f8bcb06db102dbae83058aba16e6f4729260e15e1c7a470762a261bec5460358c0fe9
DIST dpkg_1.22.14.tar.xz 5728012 BLAKE2B d14e4550f562fd054a073bfb5e9269aff82a3b582ce8676073b67c9ee72baf5a242ee62a91b56966db2569f93255a6475c75b246527142f94f3c1de91c48f673 SHA512 43b0776cf6fef8beb771c552b9824e86bbe554b0738c13ae4d1b89821c79aa2ae26a7d30d3b3b865df89374a1625adbb31da45bf208dafe87fc1a7b175fe4a28
+113
View File
@@ -0,0 +1,113 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools toolchain-funcs
DESCRIPTION="Package maintenance system for Debian"
HOMEPAGE="https://packages.qa.debian.org/dpkg"
SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.xz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+bzip2 +lzma nls selinux static-libs test +update-alternatives +zlib +zstd"
RESTRICT="!test? ( test )"
RDEPEND="
>=app-arch/gzip-1.7
>=app-arch/tar-1.34-r1
app-crypt/libmd
>=dev-lang/perl-5.32.1:=
sys-libs/ncurses:=[unicode(+)]
bzip2? ( app-arch/bzip2 )
elibc_musl? ( sys-libs/obstack-standalone )
lzma? ( app-arch/xz-utils )
nls? ( virtual/libintl )
selinux? ( sys-libs/libselinux )
zlib? ( >=sys-libs/zlib-1.1.4 )
zstd? ( app-arch/zstd:= )
"
DEPEND="
${RDEPEND}
app-arch/xz-utils
virtual/pkgconfig
test? (
dev-perl/IO-String
dev-perl/Test-Pod
virtual/perl-Test-Harness
)
"
BDEPEND="
sys-devel/flex
nls? (
app-text/po4a
>=sys-devel/gettext-0.18.2
)
"
RDEPEND+=" selinux? ( sec-policy/selinux-dpkg )"
PATCHES=(
"${FILESDIR}"/${PN}-1.22.0-flags.patch
)
src_prepare() {
default
sed -i -e 's|\<ar\>|${AR}|g' src/at/deb-format.at src/at/testsuite || die
eautoreconf
}
src_configure() {
tc-export AR CC
local myconf=(
--disable-compiler-warnings
--disable-devel-docs
--disable-dselect
--disable-start-stop-daemon
--enable-unicode
--localstatedir="${EPREFIX}"/var
$(use_enable nls)
$(use_enable update-alternatives)
$(use_with bzip2 libbz2)
$(use_with lzma liblzma)
$(use_with selinux libselinux)
$(use_with zlib libz)
$(use_with zstd libzstd)
)
econf "${myconf[@]}"
}
src_compile() {
emake AR="$(tc-getAR)"
}
src_install() {
local DOCS=( debian/changelog THANKS TODO )
default
# https://bugs.gentoo.org/835520
mv -v "${ED}"/usr/share/zsh/{vendor-completions,site-functions} || die
# https://bugs.gentoo.org/840320
insinto /etc/dpkg/origins
newins - gentoo <<-_EOF_
Vendor: Gentoo
Vendor-URL: https://www.gentoo.org/
Bugs: https://bugs.gentoo.org/
_EOF_
dosym gentoo /etc/dpkg/origins/default
keepdir \
/usr/$(get_libdir)/db/methods/{mnt,floppy,disk} \
/var/lib/dpkg/{alternatives,info,parts,updates}
find "${ED}" -name '*.la' -delete || die
if ! use static-libs; then
find "${ED}" -name '*.a' -delete || die
fi
}