dev-python/stripe: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/stripe/Manifest

@@ -1,2 +1 @@
-DIST stripe-11.4.1.tar.gz 1379118 BLAKE2B 6acbbe35ab7625d9bb0be6c92b901c71b9d93a69d5b1bfd99826cdd1288db10a87c07e88a7f66a08dece7d84767b43760c3487e9f601658b2a0d13c27f9405d5 SHA512 1bf68094002226d9b47cf29cae54116f7fb5cbc7cb000a7dc3d95eb0cbbcb75b5979348aabab4417ca455a8a28bd8d90756f6258ff0ff1c6b0af3130e8fe0563
 DIST stripe-11.5.0.tar.gz 1386601 BLAKE2B 009cd3d273a009d20ec46f7d1875212cdee92514f9735a8474eba321d92f2fed9d55ea946feecf1aaf0e456dd76c5cd651eccaad8c68838575e7655940b75e5b SHA512 2f18732d59b92b9d17f4f3b728c8457dc10457d7a2c53d80ff1f770c09f77b7d7d1627ce51f4bd37432bc41b1aab5377eecc0adaa735a6b3f45f2193e0acf4fb

dev-python/stripe/stripe-11.4.1.ebuild

@@ -1,95 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} pypy3 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Stripe Python bindings"
-HOMEPAGE="
-	https://github.com/stripe/stripe-python/
-	https://pypi.org/project/stripe/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 arm64 x86"
-IUSE="telemetry"
-
-RDEPEND="
-	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
-	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
-"
-# please bump dev-util/stripe-mock dep to the latest version on every bump
-BDEPEND="
-	test? (
-		>=dev-util/stripe-mock-0.192.0
-		dev-python/aiohttp[${PYTHON_USEDEP}]
-		dev-python/anyio[${PYTHON_USEDEP}]
-		dev-python/httpx[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/trio[${PYTHON_USEDEP}]
-		net-misc/curl
-	)
-"
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-DOCS=( LONG_DESCRIPTION.rst CHANGELOG.md README.md )
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	if ! use telemetry; then
-		sed -i -e '/enable_telemetry/s:True:False:' stripe/__init__.py || die
-	fi
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# exception message mismatch with aiohttp-3.10.0
-		"tests/test_integration.py::TestIntegration::test_async_timeout[asyncio-aiohttp]"
-		"tests/test_integration.py::TestIntegration::test_async_raw_request_timeout[asyncio-aiohttp]"
-		# Internet
-		tests/test_http_client.py::TestLiveHTTPClients::test_httpx_request_async_https
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest tests -p anyio -p pytest_mock
-}
-
-src_test() {
-	local stripe_mock_port=12111
-	local stripe_mock_max_port=12121
-	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
-	# Try to start stripe-mock until we find a free port
-	while [[ ${stripe_mock_port} -le ${stripe_mock_max_port} ]]; do
-		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
-		stripe-mock --http-port "${stripe_mock_port}" &> "${stripe_mock_logfile}" &
-		local stripe_mock_pid=${!}
-		sleep 2
-		# Did stripe-mock start?
-		curl --fail -u "sk_test_123:" \
-			"http://127.0.0.1:${stripe_mock_port}/v1/customers" &> /dev/null
-		eend ${?} "Port ${stripe_mock_port} unavailable"
-		if [[ ${?} -eq 0 ]]; then
-			einfo "stripe-mock running on port ${stripe_mock_port}"
-			break
-		fi
-		(( stripe_mock_port++ ))
-	done
-	if [[ ${stripe_mock_port} -gt ${stripe_mock_max_port} ]]; then
-		eerror "Unable to start stripe-mock for tests"
-		die "Please see the logfile located at: ${stripe_mock_logfile}"
-	fi
-
-	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
-	distutils-r1_src_test
-
-	# Tear down stripe-mock
-	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
-}