dev-python/translate-toolkit: 2.3.1 version bump

Switch to EAPI-7.
Drop python2_7 to avoid backports dependency complication.
Update minimum dep to >=dev-python/chardet-3.0.4
Add new dep on >=dev-python/pycountry-18.5.26

Package-Manager: Portage-2.3.65, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1 +1,2 @@
 DIST translate-toolkit-2.0.0.tar.gz 1106464 BLAKE2B 419caa924b36abd45cd285a28594dad7d1d49dd149961a686382f848e85d6bb15c4cbf52b28881efa7643a9470a51d2c00c57ce52c153a113296344054e31038 SHA512 a349f64438683bb00a7a7ba0537b7c9a268e6222d2df67991eb5d47b05a446a6049bf42918edc97ba8b08a89a42850eb37f6b4b917ccf5c44494885a853ffe1f
+DIST translate-toolkit-2.3.1.tar.gz 7668931 BLAKE2B b8426c06cfd01d6afcc88b629cf464e6fa91a49a6a3399cdc693395f67677bc8eeb4bb1ce0b5a1653ce0e6cafabf76cc102ab462d0482cbf311e5369f65df678 SHA512 8928d1d681dfb4cd9100ae6128f6e1d7e85ff518e6f529c37d01e34679470e9d964c08dfbb902edc23403ff6f6912d0a4236fe0cb21819d00d9ba46c3009ace3

dev-python/translate-toolkit/translate-toolkit-2.3.1.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/translate/translate/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc +html +ical +ini +subtitles +yaml"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/diff-match-patch[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.5[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-18.5.26[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( dev-python/iniparse[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	# Prevent unwanted d'loading in doc build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" \
+		-e "/html_theme/ s/sphinx-bootstrap/classic/" \
+		-i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( "${S}"/docs/_build/html/. )
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	rm -Rf docs || die
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+}