net-libs/libvncserver: fix build with cmake 4

Closes: https://bugs.gentoo.org/954087 Signed-off-by: Kostadin Shishmanov <kostadinshishmanov@protonmail.com> Part-of: https://github.com/gentoo/gentoo/pull/42349 Closes: https://github.com/gentoo/gentoo/pull/42349 Signed-off-by: Sam James <sam@gentoo.org>
2026-08-24 18:58:08 -07:00 · 2025-05-30 15:31:27 +03:00
parent 8009f09d4a
commit a80edca34c
2 changed files with 102 additions and 0 deletions
--- a/net-libs/libvncserver/files/libvncserver-0.9.15-cmake4.patch
+++ b/net-libs/libvncserver/files/libvncserver-0.9.15-cmake4.patch
@@ -0,0 +1,25 @@
+https://bugs.gentoo.org/954087
+https://github.com/LibVNC/libvncserver/commit/e64fa92
+
+From e64fa928170f22a2e21b5bbd6d46c8f8e7dd7a96 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Matti=20Lehtim=C3=A4ki?= <matti.lehtimaki@jolla.com>
+Date: Tue, 13 May 2025 08:37:07 +0300
+Subject: [PATCH] CMake: require at least CMake 3.5
+
+CMake 4 dropped support for version requirements < 3.5.
+
+Fixes building with CMake >= 4.
+---
+ CMakeLists.txt | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 205f3928..9b8118c8 100644
+--- a/CMakeLists.txt
+++ b/CMakeLists.txt
+@@ -1,4 +1,4 @@
+-cmake_minimum_required(VERSION 3.4)
+cmake_minimum_required(VERSION 3.5)
+ 
+ set(PROJECT_LANGUAGES C)
+ 
--- a/net-libs/libvncserver/libvncserver-0.9.15-r1.ebuild
+++ b/net-libs/libvncserver/libvncserver-0.9.15-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_P="LibVNCServer-${PV}"
+
+DESCRIPTION="library for creating vnc servers"
+HOMEPAGE="https://libvnc.github.io/"
+SRC_URI="https://github.com/LibVNC/${PN}/archive/${MY_P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_P}"
+
+# common/d3des.*: https://github.com/LibVNC/libvncserver/issues/88
+LICENSE="GPL-2 GPL-2+ LGPL-2.1+ BSD MIT"
+# no sub slot wanted (yet), see #578958
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+24bpp +filetransfer gnutls ipv6 +jpeg lzo +png sasl ssl systemd test +threads +zlib"
+RESTRICT="!test? ( test )"
+# https://bugs.gentoo.org/690202
+# https://bugs.gentoo.org/435326
+# https://bugs.gentoo.org/550916
+REQUIRED_USE="
+	filetransfer? ( threads )
+	jpeg? ( zlib )
+	png? ( zlib )
+	ssl? ( !gnutls? ( threads ) )
+"
+
+DEPEND="
+	>=dev-libs/libgcrypt-1.5.3:0=
+	ssl? (
+		!gnutls? ( >=dev-libs/openssl-1.0.2:0= )
+		gnutls? ( >=net-libs/gnutls-2.12.23-r6:0= )
+	)
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	lzo? ( dev-libs/lzo )
+	png? ( >=media-libs/libpng-1.6.10:0= )
+	sasl? ( dev-libs/cyrus-sasl )
+	systemd? ( sys-apps/systemd:= )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1:0= )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9.15-cmake4.patch
+)
+
+DOCS=( AUTHORS ChangeLog NEWS.md README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_EXAMPLES=OFF
+		-DWITH_FFMPEG=OFF
+		-DWITH_GTK=OFF
+		-DWITH_QT=OFF
+		-DWITH_SDL=OFF
+		-DWITH_XCB=OFF
+		-DWITH_GCRYPT=ON
+		-DWITH_24BPP=$(usex 24bpp ON OFF)
+		-DWITH_TIGHTVNC_FILETRANSFER=$(usex filetransfer ON OFF)
+		-DWITH_GNUTLS=$(usex gnutls $(usex ssl ON OFF) OFF)
+		-DWITH_IPv6=$(usex ipv6 ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_LZO=$(usex lzo ON OFF)
+		-DWITH_OPENSSL=$(usex gnutls OFF $(usex ssl ON OFF))
+		-DWITH_PNG=$(usex png ON OFF)
+		-DWITH_SASL=$(usex sasl ON OFF)
+		-DWITH_SYSTEMD=$(usex systemd ON OFF)
+		-DWITH_TESTS=$(usex test ON OFF)
+		-DWITH_THREADS=$(usex threads ON OFF)
+		-DWITH_ZLIB=$(usex zlib ON OFF)
+	)
+	cmake_src_configure
+}