kde-plasma/plasma-nm: 5.24.6 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-11-08 06:17:07 -08:00 · 2022-07-13 11:15:55 +02:00
parent 47b7233932
commit a7bd2ea3aa
2 changed files with 91 additions and 0 deletions
@@ -1,2 +1,3 @@
 DIST plasma-nm-5.24.5.tar.xz 926128 BLAKE2B 43abf81b433291432cc8d5a576ac7579c7a68f196afab106b832a8851846eebdf1562654f7186efae65f3e0942b88aa12f778eb9e5a3972cbafc62f165d07b02 SHA512 0b64b2f231d7e97f901251e274bebd53b22c19ddcfa67cc66947f48adebe61c6bde21f339896f267af22f4112b9a392d331345999000c43cb5b1e51680668ec8
+DIST plasma-nm-5.24.6.tar.xz 926272 BLAKE2B bc78ccf01f8e1d8eb34340288d68b43f040e97cb6e582f859f47e914808d0470f1c7c4bc2e9a40f95861910c23f6403a2cd1a1c82873aa21d4957f7a84dd39f1 SHA512 d5b191e301525f20bc24a083eb2d15737d3714476477b0d8f328fba59b2f790730a450dc6e647061833d75e2f1d0b92419d51d6d950331c11012a85dd97f19ca
 DIST plasma-nm-5.25.2.tar.xz 935968 BLAKE2B ce344195a01c43e07dbcc3fa8c7ab0455737e51087bce2af8e60b53e883c3b2dca0878229889bb19a08c435732e79ac49e428d8b201011cbf978388f4dca799d SHA512 5025ac852b890f67f6c8c0da5e2c21a1fc20e25c21c22f9f1dedec09fa31cf7094d1048bf4c0a969d1208e977d48292786b8c04e65076bb03a62481c0a6f66e8
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.92.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.4
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.3.0:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	net-misc/networkmanager[teamd=]
+	modemmanager? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+		net-misc/mobile-broadband-provider-info
+	)
+	openconnect? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# TODO: try to get a build switch upstreamed
+	if ! use openconnect; then
+		sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+		$(cmake_use_find_package modemmanager KF5ModemManagerQt)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}