dev-ada/libadalang: add 26.0.0

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-ada/libadalang/Manifest

@@ -1 +1,2 @@
 DIST libadalang-25.0.0.tar.gz 3056796 BLAKE2B 63719c23716d529398c68ccd203ecb3229e72dd5991a23334e1fd6fa5655acdf2a7e0a997d7b91e449d1a21935256c2c3209ab60cc532e1e5264577215c4c7ae SHA512 c625cc0018e4683bf1de18e066a806d9ed834c5e3d976904c3ad2cecc729afeb83fe9a9e00ce830dedab068e75516ac0901602c46fac33d22991bc614ab2f6aa
+DIST libadalang-26.0.0.tar.gz 3092312 BLAKE2B 8ab59faf876cc7c89e15724388e850ee7b2b120a27e8d48c78854d364e51d18d1943753cdd6b34b666b31a6e8d46e457c63533f41104c18865b1ede5fc92a27a SHA512 185c6e55cab712f8ca02b47cea469cdf0bf1befd9e2b7c45f30dc93e1105de70ceab5918c4a7f3c64f60dd8a825d689f583ebdd099c6da98092dde395626230d

dev-ada/libadalang/libadalang-26.0.0.ebuild

@@ -0,0 +1,107 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..13} )
+ADA_COMPAT=( gcc_{14..16} )
+
+inherit ada python-single-r1 multiprocessing
+
+DESCRIPTION="high performance semantic engine for the Ada programming language"
+HOMEPAGE="https://github.com/AdaCore/libadalang"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test static-libs static-pic"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${ADA_DEPS}
+	${PYTHON_DEPS}
+	~dev-ada/gpr-26.0.0[${ADA_USEDEP},static-libs?,static-pic?]
+	~dev-ada/langkit-contrib-26.0.0[${ADA_USEDEP},${PYTHON_SINGLE_USEDEP},static-libs?,static-pic?]
+	dev-python/pyyaml"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-ada/gprbuild[${ADA_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-ada/e3-core[${PYTHON_USEDEP}]
+		doc? (
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		)
+	')
+	test? ( dev-ada/e3-testsuite )"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ada_pkg_setup
+}
+
+src_prepare() {
+	default
+	rm -r testsuite/tests/{c_api,python}/gpr_ada_only || die
+	rm -r testsuite/tests/misc/lkt_typer || die
+	cd testsuite/tests/name_resolution || die
+	rm -r {abort_signal,ada2012_iterator,address_clause,at_clause} || die
+	rm -r {call_expr,deref_attribute,for_loop_6,stream_attrs} || die
+	rm -r test_subp_address || die
+}
+
+src_configure() {
+	${EPYTHON} -m langkit.scripts.lkm generate -v debug || die
+}
+
+src_compile() {
+	local libType="relocatable"
+	use static-libs && libType+=",static"
+	use static-pic  && libType+=",static-pic"
+	${EPYTHON} -m langkit.scripts.lkm build -v debug \
+		--library-types ${libType} --jobs $(makeopts_jobs) \
+		--disable-java \
+		|| die
+	if use doc; then
+		PYTHONPATH="${S}/build/python" \
+			LD_LIBRARY_PATH="${S}/build/lib/relocatable/dev" \
+			emake -C dev_manual html
+		# Needs adadomain
+		#PYTHONPATH="${S}/build/python" \
+		#	LD_LIBRARY_PATH="${S}/build/lib/relocatable/dev" \
+		#	emake -C user_manual html
+	fi
+}
+
+src_test() {
+	PATH="${S}/build/obj-mains/dev/:${PATH}" \
+		GPR_PROJECT_PATH="${S}/build" \
+		PYTHONPATH="${S}/build/python" \
+		LD_LIBRARY_PATH="${S}/build/lib/relocatable/dev" \
+		${EPYTHON} testsuite/testsuite.py || die
+}
+
+src_install() {
+	build() {
+		gprinstall -v -p -Pbuild/libadalang.gpr --prefix="${D}"/usr \
+			--build-var=LIBRARY_TYPE --build-var=LIBADALANG_LIBRARY_TYPE \
+			--sources-subdir=include/libadalang --build-name=$1 \
+			-XLIBRARY_TYPE=$1 -XGPR_BUILD=$1 -XXMLADA_BUILD=$1 || die
+	}
+	build relocatable
+	use static-libs && build static
+	use static-pic  && build static-pic
+	gprinstall -v -p -Pbuild/mains.gpr --prefix="${D}"/usr \
+		--build-var=LIBRARY_TYPE --build-var=MAINS_LIBRARY_TYPE \
+		--mode=usage --build-name=relocatable -XLIBRARY_TYPE=relocatable \
+		-XGPR_BUILD=relocatable -XXMLADA_BUILD=relocatable || die
+	python_domodule build/python/libadalang
+	if use doc; then
+		HTML_DOCS=(dev_manual/_build/html/*)
+	fi
+	einstalldocs
+}