dev-python/python-lsp-server: Bump to 1.12.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/python-lsp-server/Manifest

@@ -1,2 +1,3 @@
 DIST python_lsp_server-1.12.0.tar.gz 114328 BLAKE2B 3c94642be615822058debda5cb9de07529e7d269938029d66ade7eb7db801e7db90ae724f449e1133a813967e94bcfc71247f0392db1c495af5fff89ae66bd03 SHA512 74cbd8012f5e027fb117105302ba92e142900e88565d7f95d2dad72f2624048fff3c2c85085b648bd1ff86f6f6eb679aa34d5f6d9ae54b80e96b6ed472785b32
 DIST python_lsp_server-1.12.1.tar.gz 115002 BLAKE2B 14d4b424fa0f36d0896d699505636934255ca0057257ba4fc447faf4058327e4e2afcffab3f7dc1e81a901c9c9070c4debc69f69a2c0745bec660bfaba1e58fe SHA512 6a457bd20c5d9113a64ddbbfaabc85c6129b3900bed298622e9fc344afa342eb3a91fd8c4aa795ace063d74369d4096327d464568b16f794257e07bbb1dca5a7
+DIST python_lsp_server-1.12.2.tar.gz 115054 BLAKE2B 5ee67de14e029dc0550d9ac412ce042357938783ae00435db7147921fa4923dd7f0df9c882ce3c54b43f03c9ebec2230444174920141efc17d67c2afaf406f5d SHA512 5a24fa6a8928a36498f50aa026f84478a4193e0991a4b83cad04a7ec131ca50c0d6104feb88c34721cbeab4900e4709b2ba21013aa232a197ee81d13b78c7a0b

dev-python/python-lsp-server/python-lsp-server-1.12.2.ebuild

@@ -0,0 +1,90 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="
+	https://github.com/python-lsp/python-lsp-server/
+	https://pypi.org/project/python-lsp-server/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="all-plugins"
+
+PLUGIN_DEP="
+	>=dev-python/autopep8-2.0.4[${PYTHON_USEDEP}]
+	>=dev-python/flake8-7.1[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pyflakes-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-3.1[${PYTHON_USEDEP}]
+	>=dev-python/rope-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.1.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		${PLUGIN_DEP}
+	)
+"
+BDEPEND="
+	test? (
+		${PLUGIN_DEP}
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/qtpy[gui,testlib,${PYTHON_USEDEP}]
+	)
+"
+
+# Note: xdist breaks some tests
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	# unpin all the deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by presence of pathlib2
+		'test/plugins/test_autoimport.py'
+		# Requires pyqt5
+		'test/plugins/test_completion.py::test_pyqt_completion'
+	)
+	local EPYTEST_IGNORE=(
+		# pydocstyle is archived upstream and broken with py3.12
+		test/plugins/test_pydocstyle_lint.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}