dev-python/gevent: Bump to 20.12.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/gevent/Manifest

@@ -1 +1,2 @@
+DIST gevent-20.12.0.tar.gz 5898634 BLAKE2B a73129c7d393aedcd84b6e62c890c3b306722876a1ea4c96485096ce2ea7d1db5f03c77ea77a2c35ef41c7a96183246316c577735bcf4b25fb41095282c64d38 SHA512 76c75128ba2b33e47bd85ef2788387aa6d47d230ef9aeac4bceee03e8a2555dd204c321de7d1779fe4f44503e4fca5dce3b43c1922238da994faed0d78e5c4c1
 DIST gevent-20.9.0.tar.gz 5806581 BLAKE2B 6b1b653fa6e22539e049a9bba3d3a2b9d798a5555ce4ba60ce33ecbdf14bb5201967d22d677e1ce3170129b0763fddfcc5991347186fb102d10ae39e22538c44 SHA512 966efc945b623df2521fffadca3b7e56cae1efe6de904a724765e0593389e8b1305094baa6fbc9f4fa376b1157d0f230b01e2a90de21e4b9650614363edec9f4

dev-python/gevent/gevent-20.12.0.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+PYTHON_REQ_USE="ssl(+),threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Coroutine-based network library"
+HOMEPAGE="https://www.gevent.org/ https://pypi.org/project/gevent/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libev-4.31:=
+	dev-libs/libuv:=
+	>=net-dns/c-ares-1.12:=
+	>=dev-python/greenlet-0.4.17
+	dev-python/zope-event[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	virtual/python-greenlet[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx doc
+
+# Tests take long and fail terribly a few times.
+# It also seems that they require network access.
+#RESTRICT="test"
+
+python_prepare_all() {
+	export LIBEV_EMBED="false"
+	export CARES_EMBED="false"
+	export EMBED="false"
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	append-flags -fno-strict-aliasing
+}
+
+python_test() {
+	cd src/gevent/tests || die
+	# TODO: figure out how to make them work and not hang
+#	GEVENT_RESOLVER=ares \
+#		"${EPYTHON}" -m gevent.tests \
+#		-uall,-network \
+#		--config known_failures.py \
+#		--ignore tests_that_dont_use_resolver.txt || die
+#	GEVENT_RESOLVER=dnspython \
+#		"${EPYTHON}" -m gevent.tests \
+#		-uall,-network \
+#		--config known_failures.py \
+#		--ignore tests_that_dont_use_resolver.txt || die
+#	GEVENT_RESOLVER=thread \
+#		"${EPYTHON}" -m gevent.tests \
+#		--verbose \
+#		-uall,-network \
+#		--config known_failures.py \
+#		--ignore tests_that_dont_use_resolver.txt || die
+	GEVENT_FILE=thread \
+		"${EPYTHON}" -m gevent.tests \
+		--verbose \
+		-uall,-network \
+		--config known_failures.py \
+		test__*subprocess*.py || die
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.rst )
+	use examples && dodoc -r examples
+
+	distutils-r1_python_install_all
+}