app-misc/gramps: reactivate geography support

Suggested-By: Kevin Simmons <kevin@kblob.com>

Package-Manager: portage-2.3.2

app-misc/gramps/gramps-4.2.4-r2.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5} )
+
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1
+
+DESCRIPTION="Genealogical Research and Analysis Management Programming System"
+HOMEPAGE="https://gramps-project.org/"
+SRC_URI="https://github.com/gramps-project/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+reports +exif geo spell"
+
+RDEPEND="
+	dev-python/bsddb3[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.12:3[cairo,${PYTHON_USEDEP}]
+	dev-python/pyicu[${PYTHON_USEDEP}]
+	gnome-base/librsvg:2
+	>x11-libs/gtk+-3.14.8:3[introspection]
+	x11-libs/pango[introspection]
+	x11-misc/xdg-utils
+	reports? ( media-gfx/graphviz )
+	exif? ( >=media-libs/gexiv2-0.5[${PYTHON_USEDEP},introspection] )
+	geo? ( >=sci-geosciences/osm-gps-map-1.1.0 )
+	spell? ( app-text/gtkspell:3[introspection] )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-resourcepath.patch"
+)
+
+python_prepare_all() {
+	sed -i "s:share/doc/gramps:share/doc/${PF}:g" setup.py || die
+
+	distutils-r1_python_prepare_all
+}

app-misc/gramps/metadata.xml

@@ -92,6 +92,8 @@ na vrstni red), kar vam bo v pomoč pri vaših raziskavah, analizah in
 zapolnjevanju vrzeli v rodoslovnih podatkih.
 </longdescription>
 	<use>
+		<flag name="geo">Enable rendering of geographical data using
+			<pkg>sci-geosciences/osm-gps-map</pkg>.</flag>
 		<flag name="reports">All external software that is needed for graphical
     reports will be installed</flag>
 		<flag name="webkit">Use Webkit-based rendering for geographical