gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-05 12:38:09 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/pylint: Bump to 4.0.2

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2025-10-21 08:31:17 +02:00
parent f4a2456d5d
commit a6e4b87dbf
2 changed files with 86 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/pylint/Manifest
View File

@@ -2,3 +2,4 @@ DIST pylint-3.3.8.gh.tar.gz 1460704 BLAKE2B 9444f6f98278b300744de27796afc366a53a
DIST pylint-3.3.9.gh.tar.gz 1462472 BLAKE2B b32fcb6c0d910d74c157717aa7c6d43d8edb13aad93e48543a974ce4461f38062acd8033ff390e614bf1388ebe78de004698669d082f51861421667529c71b2b SHA512 c775cfc20540e189f5e11a15eec58687dc6c7fce4e0d75f3c984977404c758d3c6903f176f057234585e6fe2dd36f40ed0e70703d228b99ae465a03d2ccebf19
DIST pylint-4.0.0.gh.tar.gz 1506202 BLAKE2B 4a934202c6dba64e91e011c081d91d2812df720171e1f49e4e5440a8d6f8f17a431df6483f86bd25a593d85e171f8ce1cf936c3f2171c4817733f1067cc6324c SHA512 b6a92bb88d212aef142c686da53443300d9191fc61cd423082d3fb4760ff30ee8639354ec32a121a73c57cf917b7928d6982cfe02c2bdf0dac296593a1837eed
DIST pylint-4.0.1.gh.tar.gz 1506598 BLAKE2B 942368eb242b7992b1bf2ecef059c248f713ce985f453ccd95df7af63a86295b7a1e3b386fcd14c9d442a927e0d41fea6a3a2b97362d2e28df7600992899c0f2 SHA512 120bbf8d5e2379f60625de6186819969cd9fde6745e451084f652bdadd908bf7894689997969eee15842a002fd4775af88bb6810ec84f50f3e275511da00ece2
DIST pylint-4.0.2.gh.tar.gz 1507187 BLAKE2B d2ae9b5f68a0a6b781d1f46e790f045c0974743cd862a9eb0514b3b243cd55866ab8dae9dcf745f649cd245cee690c9236dff07e402a60383eaf2417a160683a SHA512 7043286b7d7bf1cc99a0ca48d7c0b95e1be77c3ba6ee09d2e6d16836e3aed6da165e1e0c78fcaafa137581e31cebcd0e40a3d6fd7ed7a979d0f5074e3df0ce84

85
dev-python/pylint/pylint-4.0.2.ebuild Normal file
View File

@@ -0,0 +1,85 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} pypy3_11 )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
MY_P=${P/_beta/b}
DESCRIPTION="Python code static checker"
HOMEPAGE="
https://pypi.org/project/pylint/
https://github.com/pylint-dev/pylint/
"
SRC_URI="
https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="examples"
RDEPEND="
<dev-python/astroid-4.1[${PYTHON_USEDEP}]
>=dev-python/astroid-4.0.1[${PYTHON_USEDEP}]
>=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
>=dev-python/isort-5.14[${PYTHON_USEDEP}]
<dev-python/isort-8[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
<dev-python/mccabe-0.8[${PYTHON_USEDEP}]
>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
>=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
$(python_gen_cond_dep '
>=dev-python/gitpython-3[${PYTHON_USEDEP}]
' 'python*' )
>=dev-python/pytest-8.3[${PYTHON_USEDEP}]
>=dev-python/typing-extensions-4.12[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=( pytest-timeout )
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# TODO
'tests/test_functional.py::test_functional[dataclass_with_field]'
'tests/test_functional.py::test_functional[no_name_in_module]'
'tests/test_functional.py::test_functional[shadowed_import]'
'tests/test_functional.py::test_functional[use_yield_from]'
)
local EPYTEST_IGNORE=(
# No need to run the benchmarks
tests/benchmark/test_baseline_benchmarks.py
)
if ! has_version "dev-python/gitpython[${PYTHON_USEDEP}]"; then
EPYTEST_IGNORE+=(
tests/profile/test_profile_against_externals.py
tests/testutils/_primer/test_package_to_lint.py
tests/testutils/_primer/test_primer.py
)
fi
epytest
}
python_install_all() {
if use examples ; then
docompress -x "/usr/share/doc/${PF}/examples"
docinto examples
dodoc -r examples/.
fi
distutils-r1_python_install_all
}