games-emulation/mednafen-jg: add 1.32.1.2

Signed-off-by: orbea <orbea@riseup.net>
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

games-emulation/mednafen-jg/Manifest

@@ -1 +1,2 @@
 DIST mednafen-1.32.1.1.tar.bz2 4430513 BLAKE2B 6cfecf12b962e46696b352c37fb1c3476e4a9a175ee65cf3f332f1f983bbec3ae0096fbbb27c3cf222a50bdb1e595f62debaf0117b10ac10c9d8b06613e55d47 SHA512 81b42120319c452347f03928aa5c7957d0906de5e413149c9f7403a6776f537ed2eadd0b41cdc45a608c246d9ceade5090755f790255017bd2223115655b20a9
+DIST mednafen-1.32.1.2.tar.bz2 4415120 BLAKE2B ebd4f94527de2b7e14a7b6541b772b21c3338bda2100d979fcfde8828a46b37c8d819f1a0c0bf2f2100144cf1a3fa70fe104c93738e346fc86c2dc48bec37ff1 SHA512 32796de3a61212e0391764e1f4931948fffa13c4aa25c96984f1f44e903e3ca7c611f24a0232866c8e0a1370ad7bb0aa6b7eeda93d3316ba70163c59a77d9ada

games-emulation/mednafen-jg/mednafen-jg-1.32.1.2.ebuild

@@ -0,0 +1,69 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_PN=${PN%-*}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Jolly Good Port of Mednafen"
+HOMEPAGE="https://gitlab.com/jgemu/mednafen"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/jgemu/${MY_PN}.git"
+else
+	SRC_URI="https://gitlab.com/jgemu/${MY_PN}/-/archive/${PV}/${MY_P}.tar.bz2"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="BSD GPL-2 GPL-2+ LGPL-2.1+ ZLIB"
+SLOT="1"
+IUSE="cpu_flags_x86_avx"
+
+DEPEND="
+	app-arch/zstd
+	dev-libs/lzo:2
+	>=dev-libs/trio-1.17
+	media-libs/flac
+	>=media-libs/jg-2.0.0
+	virtual/minizip:=
+	virtual/libiconv
+"
+RDEPEND="
+	${DEPEND}
+	games-emulation/jgrf
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	cd jollygood/conf || die
+	eautoreconf
+}
+
+src_configure() {
+	cd jollygood/conf || die
+	econf $(use_enable cpu_flags_x86_avx avx)
+}
+
+src_compile() {
+	emake -C jollygood \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		USE_EXTERNAL_TRIO=1
+}
+
+src_install() {
+	emake -C jollygood install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}"/usr \
+		DOCDIR="${EPREFIX}"/usr/share/doc/${PF} \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		USE_EXTERNAL_TRIO=1
+}