net-misc/freerdp: add 2.8.0

Signed-off-by: Mike Gilbert <floppym@gentoo.org>
2026-09-24 04:59:14 -07:00 · 2022-08-02 15:10:02 -04:00
parent 5d1adc7f70
commit a6db78f77e
2 changed files with 125 additions and 0 deletions
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -1 +1,2 @@
 DIST freerdp-2.7.0.tar.gz 7274512 BLAKE2B 82dc1403c8c2cada81585e869315ee2601d1fe87c3cb293f3cfe90278110644a5dab42ec0b516a204a651dc3127e458cd47994269644c41183501b848e399348 SHA512 9e9df14a39412f3ee3cd8a97123377d3da39492f66a0caee37d122f487639483d172cb89824523d57516aa83d22b9da569f2169a0598b475fbe70eab65fa2dc4
+DIST freerdp-2.8.0.tar.gz 7311891 BLAKE2B 56a91a5390c4c7833ac73502cafdd31723a8b70c9959d1f01c9284169d7da5e2956d2544d207c8fb9fb9f36286cfb43fa34b87ae2efc0de4bb5d3f841cd3d56e SHA512 6b1d11f560347796df9cd89e61d3879ca1cc302bc818c028c9df339aafc4ae64e9be5e7140d11d68ed63606b16bbd99e50ecbcac149f3bde5d18185d0afc51e3
--- a/net-misc/freerdp/freerdp-2.8.0.ebuild
+++ b/net-misc/freerdp/freerdp-2.8.0.ebuild
@@ -0,0 +1,124 @@
+# Copyright 2011-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+	case ${PV} in
+		2.*) EGIT_BRANCH="stable-2.0";;
+	esac
+else
+	MY_P=${P/_/-}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa cpu_flags_arm_neon cups debug doc +ffmpeg gstreamer jpeg openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:0=
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	usb? (
+		virtual/libudev:0=
+		sys-apps/util-linux:0=
+		dev-libs/dbus-glib:0=
+		virtual/libusb:1=
+	)
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		xinerama? ( x11-libs/libXinerama )
+		xv? ( x11-libs/libXv )
+	)
+	ffmpeg? ( media-video/ffmpeg:0= )
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( media-libs/libjpeg-turbo:0= )
+	openh264? ( media-libs/openh264:0= )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHANNEL_URBDRC=$(usex usb ON OFF)
+		-DWITH_ALSA=$(usex alsa ON OFF)
+		-DWITH_CCACHE=OFF
+		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
+		-DWITH_MANPAGES=$(usex doc ON OFF)
+		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_SWSCALE=$(usex ffmpeg ON OFF)
+		-DWITH_CAIRO=$(usex ffmpeg OFF ON)
+		-DWITH_DSP_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DWITH_OPENH264=$(usex openh264 ON OFF)
+		-DWITH_PULSE=$(usex pulseaudio ON OFF)
+		-DWITH_SERVER=$(usex server ON OFF)
+		-DWITH_PCSC=$(usex smartcard ON OFF)
+		-DWITH_LIBSYSTEMD=$(usex systemd ON OFF)
+		-DWITH_X11=$(usex X ON OFF)
+		-DWITH_XINERAMA=$(usex xinerama ON OFF)
+		-DWITH_XV=$(usex xv ON OFF)
+		-DWITH_WAYLAND=$(usex wayland ON OFF)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=()
+	use elibc_musl && myctestargs+=( -E TestBacktrace )
+	cmake_src_test
+}