net-misc/nextcloud-client: add 3.5.2

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

net-misc/nextcloud-client/Manifest

@@ -1,2 +1,3 @@
 DIST nextcloud-client-3.4.4.tar.gz 14352142 BLAKE2B 104af477a15adc30885bd4d6c5fa022efc89d63c9294c8a632349999ed60b95ad1a34bdc8fed8602fd60f4fbff7c9dca2c33461bf9b167401b8d933ef9b02821 SHA512 880d615147feed915595bf6e4f99c3c7588d03b910bdee934429ccdbc16c2a0e7b07be99665729d60cb68c22a140cfd21c0cc821fd1c4499bc6ea4aec515eaf4
 DIST nextcloud-client-3.5.1.tar.gz 15392337 BLAKE2B 6f3826e33828aacfbefb1786c9a1231ccba0be4b649cc132546914d7c61b8755b32f873a9eb5c27d10d207121636738bc51354643d056ffe6733c5cd0f395cac SHA512 989cc4c99f81f7451af8b13453155f0c89448226ade565025030a8064c7e54e5668b37744564685cc700f2b5a54f899d563a4be2bfe023e43987928982a2feba
+DIST nextcloud-client-3.5.2.tar.gz 15433543 BLAKE2B 082031ac34a644f0db09679ef34237ee8fc9def88ff4659ad4a71e3ac611b3be3f9a0750deda25cd0ef34aca7e9d3c60fe7d3fc5a4d747eef46978e2fe84b742 SHA512 2892c277466869e3872a68049541c3d5afe94ca4dde1e97ea13ac615adedba198946763b5ff5dcb4694a9cec1946e35d1d6b6fd950d26b23cd6ddd94181f4b83

net-misc/nextcloud-client/nextcloud-client-3.5.2.ebuild

@@ -0,0 +1,106 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake virtualx xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86"
+IUSE="doc dolphin nautilus test webengine"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=dev-db/sqlite-3.34:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain:=[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	sys-libs/zlib
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtxml:5
+	gnome-base/librsvg
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)
+"
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/desktop-${PV/_/-}"
+
+src_prepare() {
+	# We do not package libcloudproviders
+	sed -e "s/pkg_check_modules.*cloudproviders/#&/" -i CMakeLists.txt || die
+
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_UPDATER=OFF
+		$(cmake_use_find_package doc Sphinx)
+		$(cmake_use_find_package doc PdfLatex)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_SHELL_INTEGRATION_NAUTILUS=$(usex nautilus)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_compile() {
+	local compile_targets=(all)
+	if use doc; then
+		compile_targets+=(doc doc-man)
+	fi
+	cmake_src_compile ${compile_targets[@]}
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}