x11-wm/dwm: Version 6.2

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

x11-wm/dwm/Manifest

@@ -1 +1,2 @@
 DIST dwm-6.1.tar.gz 25887 BLAKE2B 36c3aa36b8371b993ac845faaebd738f8295d3bed34a1a97075d8449cb3a2febec746b21858071579e27021502c7e184fcb0750997eacce471b968bac0e555bf SHA512 875644bbc246088f2c87e50debbadd4bc179444b396b1b327149087e8bc5303325ebc9103a7e3c864266ee1ac683ea3cd8f0a08285c8e46fc4389d5b83a555f1
+DIST dwm-6.2.tar.gz 25273 BLAKE2B 2bb9e5b900a1d73f3eb94cb8454580ec98930dbacbabec1f2bbd394eb96696873434b6ddea4ac95eb9d171de2c09c5d4ca0b30649836f7e25f4769f44d25a6eb SHA512 01abcab954e5b7c20d011e6fd9c28025271fea2e85610c928812f7c6a09f99d7f9e93d11ffc2d6a7aca894b3fa7e507c6c2fe5f26ff5ddcfc650a9bbaaa41e06

x11-wm/dwm/dwm-6.2.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="a dynamic window manager for X11"
+HOMEPAGE="https://dwm.suckless.org/"
+SRC_URI="https://dl.suckless.org/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="xinerama"
+
+RDEPEND="
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	xinerama? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s/ -Os / /" \
+		-e "/^\(LDFLAGS\|CFLAGS\|CPPFLAGS\)/{s| = | += |g;s|-s ||g}" \
+		config.mk || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	if use xinerama; then
+		emake CC=$(tc-getCC) dwm
+	else
+		emake CC=$(tc-getCC) XINERAMAFLAGS="" XINERAMALIBS="" dwm
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/dwm-session2 dwm
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}"/dwm.desktop
+
+	dodoc README
+
+	save_config config.h
+}

x11-wm/dwm/dwm-9999.ebuild

@@ -1,7 +1,7 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 inherit git-r3 toolchain-funcs
 
 DESCRIPTION="a dynamic window manager for X11"
@@ -28,19 +28,9 @@ src_prepare() {
 	default
 
 	sed -i \
-		-e "s/CFLAGS = -std=c99 -pedantic -Wall -Os/CFLAGS += -std=c99 -pedantic -Wall/" \
-		-e "/^LDFLAGS/{s|=|+=|g;s|-s ||g}" \
-		-e "s/#XINERAMALIBS =/XINERAMALIBS ?=/" \
-		-e "s/#XINERAMAFLAGS =/XINERAMAFLAGS ?=/" \
-		-e "s@/usr/X11R6/include@${EPREFIX}/usr/include/X11@" \
-		-e "s@/usr/X11R6/lib@${EPREFIX}/usr/lib@" \
-		-e "s@-I/usr/include@@" -e "s@-L/usr/lib@@" \
-		-e "s/\/freetype2/\ -I\/usr\/include\/freetype2/" \
+		-e "s/ -Os / /" \
+		-e "/^\(LDFLAGS\|CFLAGS\|CPPFLAGS\)/{s| = | += |g;s|-s ||g}" \
 		config.mk || die
-	sed -i \
-		-e '/@echo CC/d' \
-		-e 's|@${CC}|$(CC)|g' \
-		Makefile || die
 }
 
 src_compile() {