dev-vcs/tig: add 2.5.10

Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

dev-vcs/tig/Manifest

@@ -1 +1,2 @@
+DIST tig-2.5.10.tar.gz 1183631 BLAKE2B a2d58e9a79bf7fdabf74704a04f2d0dee30e8fd348319786ab639119c0912c3dc632a143ef586b24f33841a040f1c06101cb52f3a8e8e8a7ee36cc175685fba9 SHA512 6b89a2edebfc58cd2f5e855bbd2137ba4e1be65e793c04a7a9858f3a32b31681f5a80f33e5c1d2d69104e4c37817d806a70ab9a1fc8807d5f49751d4f283d788
 DIST tig-2.5.8.tar.gz 1179844 BLAKE2B eff20358443bd794de2985e1c76db8be25f4461ac82182a72004ab380156c15c5ed27dc1c66fb347b1f3d1ccddcead0a031638762e48f7e88a3b0593a278d3d7 SHA512 f4e7648ae7c58e936251f69071a092617368a04eabb4ae6726b2de1dbd305c559b7235f7aa70868f4ada02611196593a6e1c241062f57cd05a9c98685385053e

dev-vcs/tig/tig-2.5.10.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/jonas/tig.git"
+	inherit git-r3 autotools
+else
+	SRC_URI="https://github.com/jonas/tig/releases/download/${P}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+DESCRIPTION="text mode interface for git"
+HOMEPAGE="https://jonas.github.io/tig/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="pcre test unicode"
+REQUIRED_USE="test? ( unicode )"
+
+DEPEND="
+	sys-libs/ncurses:=[unicode(+)?]
+	sys-libs/readline:0=
+	pcre? ( dev-libs/libpcre2:= )
+"
+RDEPEND="
+	${DEPEND}
+	dev-vcs/git
+"
+[[ ${PV} == "9999" ]] && BDEPEND+=" app-text/asciidoc app-text/xmlto"
+
+# encoding/env issues
+RESTRICT="test"
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with pcre) \
+		$(use_with unicode ncursesw)
+}
+
+src_compile() {
+	emake V=1
+	[[ ${PV} == "9999" ]] && emake V=1 doc-man doc-html
+}
+
+src_test() {
+	# workaround parallel test failures
+	LC_ALL=en_US.utf8 emake -j1 test
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-doc-man
+	dodoc doc/manual.html README.html NEWS.html
+	newbashcomp contrib/tig-completion.bash ${PN}
+
+	docinto examples
+	dodoc contrib/*.tigrc
+}