dev-python/ansible-pylibssh: new package, add 1.3.0

Bug: https://bugs.gentoo.org/965995

Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

dev-python/ansible-pylibssh/Manifest

@@ -0,0 +1 @@
+DIST ansible-pylibssh-1.3.0.tar.gz 151535 BLAKE2B e37118138d4e88a256576f4e50467e2b5383234c583ef74af0807735380b5558e2b2f3655c5b91cb119ccf0f0cee470527edc0a40658385c3979a7e1940390ab SHA512 45213bab7cfc6984ccd64ddaae180a8ad9766bcd96c97d5776f2a915fcc7a2b2db1e1ae3b0675f7581fe925a4d15cd8a25f36703218319422543f01c0ad045de

dev-python/ansible-pylibssh/ansible-pylibssh-1.3.0.ebuild

@@ -0,0 +1,59 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python bindings for libssh client specific to Ansible use case"
+HOMEPAGE="
+	https://github.com/ansible/pylibssh/
+	https://pypi.org/project/ansible-pylibssh/
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+# keywords needed for ansible
+# ~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~x64-macos
+
+RDEPEND="
+	>=net-libs/libssh-0.9.0:=
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		virtual/ssh
+	)
+"
+
+EPYTEST_PLUGINS=()
+# tests have tendency to hang if something goes wrong
+: ${EPYTEST_TIMEOUT:=30}
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# Tests require an account that you can login to.
+	# They would work by spawning sshd with PermitEmptyPasswords and then ssh'in in with the current user.
+	# "portage" and every other portage installable user is nologin.
+	# Adding a user that allows logging in does not seem reasonable.
+	EPYTEST_IGNORE=(
+		tests/unit/scp_test.py
+		tests/unit/sftp_test.py
+		tests/unit/channel_test.py
+	)
+	EPYTEST_DESELECT=(
+		tests/integration/sshd_test.py::test_sshd_addr_fixture_port
+	)
+	# pytest.ini adds alls sorts of stuff like pytest-cov
+	epytest -o addopts=
+}

dev-python/ansible-pylibssh/metadata.xml

@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://github.com/ansible/pylibssh/issues</bugs-to>
+		<doc>https://ansible-pylibssh.readthedocs.io/</doc>
+		<remote-id type="github">ansible/pylibssh</remote-id>
+		<remote-id type="pypi">ansible-pylibssh</remote-id>
+	</upstream>
+</pkgmetadata>