dev-python/uvloop: Bump to 0.17.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/uvloop/Manifest

@@ -1,2 +1,3 @@
 DIST uvloop-0.15.3.tar.gz 2094066 BLAKE2B 77ae4634ee31211dba13f41aede4480d70271e042a30a1268e9ad18f5de2b296b84931fb6b2022d2351f33521a84264f74cbc30caa5ff84b0f429bc9f1d426a0 SHA512 5687371a13509bdac0ef7a5ca0f7c78b54d0d9225cbf68cebc6d4fdf3807c2e3346579f5440eb0ff6578088780cc5efb09fba114da0bc0e60ad3f607d9df652f
 DIST uvloop-0.16.0.tar.gz 2129067 BLAKE2B 8a5a5c760b1036428483d2cf1f509784aa61cb69388720775c9555bdb0ce19341cb58fc051ab6f92066a3478acf729513dafafd79f31115b064bf1d3660479de SHA512 dd6dcec38f7f94dc0cf0123302fd6fe404428196b452a80a8258a207654e3f67e210233be3d649668c22b48390232d0347706b1d87fb50016287142c742b806d
+DIST uvloop-0.17.0.tar.gz 2279973 BLAKE2B 7ccbf3b8e723e36c1010a70e256de0ad1a9728fe10b3538e05c57157b16ea7e5369347c855cd1460e49f89197ebb05628c4b6fcd7e50c623b1aaa5890ac64b5f SHA512 861d7f28ad879ecbfa40d53b9626e38660f02618fd433edbd5a8ea5100a17ade042a26549def04bc23f928aca3adc83d62503f0548038cd400284f5654003ee4

dev-python/uvloop/uvloop-0.17.0.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Ultra-fast implementation of asyncio event loop on top of libuv"
+HOMEPAGE="
+	https://github.com/magicstack/uvloop/
+	https://pypi.org/project/uvloop/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 -riscv ~sparc ~x86"
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples"
+
+DEPEND="
+	>=dev-libs/libuv-1.11.0:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-python/cython-0.29.32[${PYTHON_USEDEP}]
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-22.0.0[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	rm -r vendor || die
+	cat <<-EOF >> setup.cfg || die
+		[build_ext]
+		use_system_libuv=True
+		cython_always=True
+	EOF
+
+	# flake8 only
+	#rm tests/test_sourcecode.py || die
+	# force cythonization
+	rm uvloop/loop.c || die
+	# hangs
+	#sed -i -e 's:test_remote_shutdown_receives_trailing_data:_&:' \
+	#	tests/test_tcp.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local EPYTEST_IGNORE=(
+		# linting
+		tests/test_sourcecode.py
+	)
+	local EPYTEST_DESELECT=(
+		# TODO: expects some... cython_helper?
+		tests/test_libuv_api.py::Test_UV_libuv::test_libuv_get_loop_t_ptr
+		# unhappy about sandbox injecting its envvars
+		tests/test_process.py::Test_UV_Process::test_process_env_2
+		tests/test_process.py::Test_AIO_Process::test_process_env_2
+		# hangs
+		tests/test_tcp.py::Test_AIO_TCPSSL::test_remote_shutdown_receives_trailing_data
+	)
+
+	rm -rf uvloop || die
+	epytest -s
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}