dev-python/python-manilaclient: New package, v6.2.0

Import from ::guru.  Thanks to Niklaus 'vimja' Hofer for the hard work!

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/python-manilaclient/Manifest

@@ -0,0 +1 @@
+DIST python_manilaclient-6.2.0.tar.gz 304351 BLAKE2B 1e8f99c438b8ee12c0def7c81ad21804ad7f77818fdc16c7314fe9c0bafba961db24518125affd7ecfc6379749ce380b5945dc1cccdcadcb3b2ebc64b2ed68ca SHA512 621152fb1051acc66d3dc8c84d7c9b03e064755cb8957d85802bc0fb8948f53ea3798f0d3e821897f5a638a7de6551bf1afde400b3fbc43f7d5d98b93b56ee65

dev-python/python-manilaclient/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">python-manilaclient</remote-id>
+		<remote-id type="github">openstack/python-manilaclient</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/python-manilaclient/python-manilaclient-6.2.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python bindings to the OpenStack Manila API"
+HOMEPAGE="
+	https://opendev.org/openstack/python-manilaclient
+	https://github.com/openstack/python-manilaclient/
+	https://pypi.org/project/python-manilaclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pbr-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/python-openstackclient-10.1.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# requires tempest
+	rm manilaclient/tests/unit/test_functional_utils.py || die
+
+	distutils-r1_src_prepare
+
+}
+
+python_test() {
+	# functional tests require the OpenStack manila service
+	eunittest manilaclient/tests/unit
+}

profiles/features/wd40/package.mask

@@ -450,6 +450,7 @@ dev-python/pytest-trio
 dev-python/python-glanceclient
 dev-python/python-ironicclient
 dev-python/python-jose
+dev-python/python-manilaclient
 dev-python/python-neutronclient
 dev-python/python-openstackclient
 dev-python/python-snappy