mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
dev-python/pandas: Remove old
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
@@ -1,6 +1,4 @@
|
||||
DIST pandas-2.2.3.tar.gz 4399213 BLAKE2B eca6d31b21f6385c606b3c6f8f4eedc5871719ad5e039e99c01cc16e335a493c2159d208c2d88b573b661adbeaf1172ea1296d13d51b60602966cbc344dc367b SHA512 9bbff5cf51d7fe5e53b207b3593ba92560dabb15294d6509c5be55e0c2a737fad156ca46e56a7e0bfba7d791edfbcbdf885d6f82e2e1a48b2d5e0fc0ef5e56f5
|
||||
DIST pandas-2.3.3.tar.gz 4495223 BLAKE2B c31604617900d439020dcdd66fcbca1cf3b720b6f4dd8ea51891946ad04774754cf7636a2ffb9fe746d15911a88153d36d4033b6a0207e9c7a1653a0f677570d SHA512 4179acb9fd9d1c5d543bb19b22483b4c2b17a36d5b10270a02ff4d8370b43c16a93673bf5509a5b1d1c960c0fde9238bbbf5b309c6745d2abf3d934535f3fd85
|
||||
DIST pandas-3.0.0.tar.gz 4633005 BLAKE2B 7084d2098e2f95c339c7638333161285e3bc969d0ba68df485c316445ab572ab99f2f4abfac5e22fa117c3af7a45cc412f95822996b75cabb489cc3e1d25673b SHA512 da05f1dc83caeacc95f5d5c84fec1949eea9bc4acd4763a8204a83174c5f45a6555410cac16241a530a584565963c6f6f7ffa7718c31e93d61dc7a47d8fa6c1f
|
||||
DIST pandas-3.0.0.tar.gz.provenance 9455 BLAKE2B 22caafd024bd01c8afc97b764ec19a71a4cdf4c2838d9853720ba801e280e5dbd587de2822805617b78bbf9d95c0b6eb81786a30e30aeb2224f9100855678e34 SHA512 b756eb102dc05afb1eed2ff22177dda0fdc0cc54db1ac45a3115748d7d7c09610d9332276bd448fcebb50a1e66242b2131b2e251b67bdedbad56e6b285728581
|
||||
DIST pandas-3.0.2.tar.gz 4645855 BLAKE2B 9d8ccd481d42040a45b990c84acd1ef7ca842bc3e0f80827875aabdf8c4278a2b2f0cedacfd8b73dca4ef36037162fef63e1feffb46d4522c6cc794d9a2052d6 SHA512 71a50f40812f0a5ac80068cc79fb3ec8685f9e21b15ba6cda136465b1258aef5fd8ab4d9b677ef53c6b3f3e8d9939a058457594754c34f9aa6748fc641720ab3
|
||||
DIST pandas-3.0.2.tar.gz.provenance 9326 BLAKE2B 11ae41e6c60a15415cbed7f43ecd90a23bd8a465588c73002d197706fc2d5680cfb1471a0f5061d27310f01101c99514ed7088649101d49515722093cd54d7a5 SHA512 402b810942056a62eba500802b1bdf5e8db28df3b47e0fb71340a360ee2c2348a0875b877f72e7c6de21f04980d72a8f547838e050a9bbcbd7bcfea0eb117b02
|
||||
|
||||
@@ -1,200 +0,0 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_EXT=1
|
||||
DISTUTILS_USE_PEP517=meson-python
|
||||
PYPI_VERIFY_REPO=https://github.com/pandas-dev/pandas
|
||||
PYTHON_COMPAT=( python3_{11..14} )
|
||||
PYTHON_REQ_USE="threads(+)"
|
||||
|
||||
VIRTUALX_REQUIRED="manual"
|
||||
|
||||
inherit distutils-r1 optfeature pypi toolchain-funcs virtualx
|
||||
|
||||
DESCRIPTION="Powerful data structures for data analysis and statistics"
|
||||
HOMEPAGE="
|
||||
https://pandas.pydata.org/
|
||||
https://github.com/pandas-dev/pandas/
|
||||
https://pypi.org/project/pandas/
|
||||
"
|
||||
|
||||
LICENSE="BSD"
|
||||
SLOT="0"
|
||||
if [[ ${PV} != *_rc* ]]; then
|
||||
KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
|
||||
fi
|
||||
IUSE="big-endian full-support minimal test X"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RECOMMENDED_DEPEND="
|
||||
>=dev-python/bottleneck-1.3.4[${PYTHON_USEDEP}]
|
||||
>=dev-python/numexpr-2.8.0[${PYTHON_USEDEP}]
|
||||
"
|
||||
|
||||
# TODO: add pandas-gbq to the tree
|
||||
# TODO: Re-add dev-python/statsmodel[python3_11] dep once it supports python3_11
|
||||
# https://github.com/statsmodels/statsmodels/issues/8287
|
||||
OPTIONAL_DEPEND="
|
||||
>=dev-python/beautifulsoup4-4.14.2[${PYTHON_USEDEP}]
|
||||
dev-python/blosc[${PYTHON_USEDEP}]
|
||||
>=dev-python/html5lib-1.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/jinja2-3.1.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/lxml-4.8.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/matplotlib-3.6.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/openpyxl-3.0.7[${PYTHON_USEDEP}]
|
||||
>=dev-python/sqlalchemy-1.4.36[${PYTHON_USEDEP}]
|
||||
>=dev-python/tabulate-0.8.10[${PYTHON_USEDEP}]
|
||||
>=dev-python/xarray-2022.3.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/xlrd-2.0.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/xlsxwriter-3.0.3[${PYTHON_USEDEP}]
|
||||
>=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
|
||||
!arm? ( !hppa? ( !ppc? ( !x86? (
|
||||
>=dev-python/scipy-1.8.1[${PYTHON_USEDEP}]
|
||||
dev-python/statsmodels[${PYTHON_USEDEP}]
|
||||
) ) ) )
|
||||
!big-endian? (
|
||||
>=dev-python/tables-3.7.0[${PYTHON_USEDEP}]
|
||||
)
|
||||
X? (
|
||||
|| (
|
||||
>=dev-python/pyqt5-5.15.6[${PYTHON_USEDEP}]
|
||||
>=dev-python/qtpy-2.2.0[${PYTHON_USEDEP}]
|
||||
x11-misc/xclip
|
||||
x11-misc/xsel
|
||||
)
|
||||
)
|
||||
"
|
||||
DEPEND="
|
||||
>=dev-python/numpy-2.3.3:=[${PYTHON_USEDEP}]
|
||||
"
|
||||
COMMON_DEPEND="
|
||||
${DEPEND}
|
||||
>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
|
||||
"
|
||||
BDEPEND="
|
||||
${COMMON_DEPEND}
|
||||
>=dev-build/meson-1.2.1
|
||||
>=dev-python/cython-3.0.5[${PYTHON_USEDEP}]
|
||||
>=dev-python/versioneer-0.28[${PYTHON_USEDEP}]
|
||||
test? (
|
||||
${VIRTUALX_DEPEND}
|
||||
${RECOMMENDED_DEPEND}
|
||||
${OPTIONAL_DEPEND}
|
||||
dev-libs/apache-arrow[brotli,parquet,snappy]
|
||||
>=dev-python/beautifulsoup4-4.14.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/hypothesis-6.46.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/openpyxl-3.0.10[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyarrow-10.0.1[parquet,${PYTHON_USEDEP}]
|
||||
>=dev-python/pymysql-1.0.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/xlsxwriter-3.0.3[${PYTHON_USEDEP}]
|
||||
x11-misc/xclip
|
||||
x11-misc/xsel
|
||||
)
|
||||
"
|
||||
RDEPEND="
|
||||
${COMMON_DEPEND}
|
||||
!minimal? ( ${RECOMMENDED_DEPEND} )
|
||||
full-support? ( ${OPTIONAL_DEPEND} )
|
||||
"
|
||||
|
||||
EPYTEST_PLUGINS=()
|
||||
EPYTEST_XDIST=1
|
||||
distutils_enable_tests pytest
|
||||
|
||||
src_test() {
|
||||
virtx distutils-r1_src_test
|
||||
}
|
||||
|
||||
python_test() {
|
||||
# Note; deselects relative to pandas/
|
||||
local EPYTEST_DESELECT=(
|
||||
# missing data not covered by --no-strict-data-files?
|
||||
# https://github.com/pandas-dev/pandas/issues/63437
|
||||
tests/io/test_common.py::test_read_csv_chained_url_no_error
|
||||
|
||||
# require -Werror
|
||||
# https://github.com/pandas-dev/pandas/pull/63436
|
||||
tests/config/test_config.py::TestConfig::test_case_insensitive
|
||||
|
||||
# deprecation warning
|
||||
'tests/computation/test_eval.py::TestEval::test_scalar_unary[numexpr-pandas]'
|
||||
)
|
||||
|
||||
if ! tc-has-64bit-time_t; then
|
||||
EPYTEST_DESELECT+=(
|
||||
# Needs 64-bit time_t (TODO: split into 32-bit arch only section)
|
||||
tests/tseries/offsets/test_year.py::test_add_out_of_pydatetime_range
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-BusinessDay]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-BusinessHour]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-BusinessMonthEnd]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-BusinessMonthBegin]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-BQuarterEnd]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-BQuarterBegin]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-CustomBusinessDay]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-CustomBusinessHour]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-CustomBusinessMonthEnd]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-CustomBusinessMonthBegin]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-MonthEnd]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-MonthBegin]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-SemiMonthBegin]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-SemiMonthEnd]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-QuarterEnd]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-LastWeekOfMonth]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-WeekOfMonth]'
|
||||
'tests/tseries/offsets/test_common.py::test_apply_out_of_range[tzlocal()-Week]'
|
||||
)
|
||||
fi
|
||||
|
||||
if ! has_version "dev-python/scipy[${PYTHON_USEDEP}]"; then
|
||||
EPYTEST_DESELECT+=(
|
||||
tests/plotting/test_misc.py::test_savefig
|
||||
)
|
||||
fi
|
||||
|
||||
case ${EPYTHON} in
|
||||
python3.14)
|
||||
EPYTEST_DESELECT+=(
|
||||
'tests/computation/test_eval.py::TestEval::test_simple_cmp_ops[float-float-numexpr-pandas-in]'
|
||||
'tests/computation/test_eval.py::TestEval::test_simple_cmp_ops[float-float-numexpr-pandas-not in]'
|
||||
'tests/computation/test_eval.py::TestEval::test_simple_cmp_ops[float-float-python-pandas-in]'
|
||||
'tests/computation/test_eval.py::TestEval::test_simple_cmp_ops[float-float-python-pandas-not in]'
|
||||
'tests/computation/test_eval.py::TestEval::test_compound_invert_op[float-float-numexpr-pandas-in]'
|
||||
'tests/computation/test_eval.py::TestEval::test_compound_invert_op[float-float-numexpr-pandas-not in]'
|
||||
'tests/computation/test_eval.py::TestEval::test_compound_invert_op[float-float-python-pandas-in]'
|
||||
'tests/computation/test_eval.py::TestEval::test_compound_invert_op[float-float-python-pandas-not in]'
|
||||
'tests/computation/test_eval.py::TestOperations::test_simple_arith_ops[numexpr-pandas]'
|
||||
'tests/computation/test_eval.py::TestOperations::test_simple_arith_ops[python-pandas]'
|
||||
)
|
||||
;;
|
||||
esac
|
||||
|
||||
local -x LC_ALL=C.UTF-8
|
||||
cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
|
||||
"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
|
||||
# nonfatal from virtx
|
||||
# --no-strict-data-files is necessary since upstream prevents data
|
||||
# files from even being included in GitHub archives, sigh
|
||||
# https://github.com/pandas-dev/pandas/issues/54907
|
||||
nonfatal epytest pandas/tests \
|
||||
--no-strict-data-files -o xfail_strict=false \
|
||||
-m "not single_cpu and not slow and not network and not db" ||
|
||||
die "Tests failed with ${EPYTHON}"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
|
||||
optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
|
||||
optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup4 dev-python/html5lib dev-python/lxml
|
||||
optfeature "for msgpack compression using blosc" dev-python/blosc
|
||||
optfeature "Template engine for conditional HTML formatting" dev-python/jinja2
|
||||
optfeature "Plotting support" dev-python/matplotlib
|
||||
optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.10" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
|
||||
optfeature "necessary for HDF5-based storage" ">=dev-python/tables-3.7.0"
|
||||
optfeature "R I/O support" dev-python/rpy2
|
||||
optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
|
||||
optfeature "SQL database support" ">=dev-python/sqlalchemy-1.4.36"
|
||||
optfeature "miscellaneous statistical functions" dev-python/scipy
|
||||
optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/pyqt5 dev-python/qtpy x11-misc/xclip x11-misc/xsel
|
||||
}
|
||||
Reference in New Issue
Block a user