sys-apps/ucspi-unix: bump EAPI

also
- remove "A " from DESCRIPTION
- remove empty IUSE
- remove dead block RDEPEND
- remove unneeded DOCS

Signed-off-by: Filip Kobierski <fkobi@pm.me>
Part-of: https://github.com/gentoo/gentoo/pull/42059
Closes: https://github.com/gentoo/gentoo/pull/42059
Signed-off-by: Sam James <sam@gentoo.org>

sys-apps/ucspi-unix/ucspi-unix-1.0-r1.ebuild

@@ -0,0 +1,28 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="UCSPI implementation for Unix domain sockets"
+HOMEPAGE="https://untroubled.org/ucspi-unix/"
+SRC_URI="https://untroubled.org/ucspi-unix/archive/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~loong ~riscv ~sparc ~x86"
+
+# We statically link bglibs.
+DEPEND=">=dev-libs/bglibs-2.04"
+
+src_configure() {
+	echo "$(tc-getCC) ${CFLAGS} -D_GNU_SOURCE" > conf-cc || die
+	echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
+}
+
+src_install() {
+	dobin unixserver unixclient unixcat
+	doman unixserver.1 unixclient.1
+	dodoc NEWS PROTOCOL README
+}