media-sound/hydrogen: bump to 1.1.0 + updated live

upstream dropped support for jack session

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

media-sound/hydrogen/Manifest

@@ -1 +1,2 @@
 DIST hydrogen-1.0.2.tar.gz 11533410 BLAKE2B a4210e666b11e173eb0e02728f601ac9811941b558096ae76f3ad45b91c5db1ff942cddd536a50f8f2f456871d69f3a6c52d53c926f4547f13783ccbb4fc250d SHA512 7466b7ef1da4a078d67e1cab8744b2e0c3c048bb55e1febd22023c591ed9e2bf1cea41adc38a775a2ac60978735517a92df404d5ca8bb13603ea68c8da70daa9
+DIST hydrogen-1.1.0.tar.gz 11413446 BLAKE2B 8008336d2199bf36d9efca8875217e4a5f3d66c0274e25334525292e7864ca1dc4da75f86cbba981dfdbc19a3dbafebff503ce1ef597adae56fc467b44611a19 SHA512 116380be03f03a9294e278be5c7ede90fe088f21bf31db46a5e5df2684d11676e518200e6c4a187063c769f5b97950af9602b9b2694ca37788f73a2666265cc8

media-sound/hydrogen/hydrogen-1.1.0.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Advanced drum machine"
+HOMEPAGE="http://www.hydrogen-music.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}-music/${PN}"
+else
+	MY_PV=${PV/_/-}
+	SRC_URI="https://github.com/${PN}-music/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+fi
+
+LICENSE="GPL-2 ZLIB"
+SLOT="0"
+IUSE="alsa +archive doc jack ladspa lash osc oss portaudio portmidi pulseaudio"
+
+REQUIRED_USE="lash? ( alsa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+CDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	>=media-libs/libsndfile-1.0.18
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	!archive? ( >=dev-libs/libtar-1.2.11-r3 )
+	jack? ( virtual/jack )
+	ladspa? ( media-libs/liblrdf )
+	lash? ( media-sound/lash )
+	osc? ( media-libs/liblo )
+	portaudio? ( media-libs/portaudio )
+	portmidi? ( media-libs/portmidi )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+DEPEND="
+	${CDEPEND}
+	dev-qt/qttest:5
+"
+RDEPEND="${CDEPEND}"
+
+DOCS=( AUTHORS ChangeLog DEVELOPERS README.txt )
+
+PATCHES=(
+	"${FILESDIR}/${P}-gnuinstalldirs.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWANT_ALSA=$(usex alsa)
+		-DWANT_CPPUNIT=OFF
+		-DWANT_DEBUG=OFF
+		-DWANT_JACK=$(usex jack)
+		-DWANT_LADSPA=$(usex ladspa)
+		-DWANT_LASH=$(usex lash)
+		-DWANT_LIBARCHIVE=$(usex archive)
+		-DWANT_LRDF=$(usex ladspa)
+		-DWANT_OSC=$(usex osc)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PORTAUDIO=$(usex portaudio)
+		-DWANT_PORTMIDI=$(usex portmidi)
+		-DWANT_PULSEAUDIO=$(usex pulseaudio)
+		-DWANT_RUBBERBAND=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/docs/html/. )
+	cmake_src_install
+}

media-sound/hydrogen/hydrogen-9999.ebuild

@@ -57,7 +57,7 @@ RDEPEND="${CDEPEND}"
 DOCS=( AUTHORS ChangeLog DEVELOPERS README.txt )
 
 PATCHES=(
-	"${FILESDIR}/${P}-gnuinstalldirs.patch"
+	"${FILESDIR}/${PN}-1.1.0-gnuinstalldirs.patch"
 )
 
 src_prepare() {
@@ -70,7 +70,6 @@ src_configure() {
 		-DWANT_CPPUNIT=OFF
 		-DWANT_DEBUG=OFF
 		-DWANT_JACK=$(usex jack)
-		-DWANT_JACKSESSION=$(usex jack)
 		-DWANT_LADSPA=$(usex ladspa)
 		-DWANT_LASH=$(usex lash)
 		-DWANT_LIBARCHIVE=$(usex archive)