app-crypt/eid-mw: add 5.1.23

Closes: https://bugs.gentoo.org/934996
Signed-off-by: Amy Liffey <amynka@gentoo.org>

app-crypt/eid-mw/Manifest

@@ -1 +1,2 @@
 DIST eid-mw-5.1.21.tar.gz 16299868 BLAKE2B 9b01b25782ca8d64c1abf9beadf556f4691af5ba68deb3d0fb25a6b9ba13c845565aa5308360f3ebe69ec88871d60f3f1340178cd6133429946a5ebcdd249ad8 SHA512 f94a7c6fb6b72603adeb1e8e42bccddb0917b2597f0826736974e120d3ece6cc17242999790209d6a8e440545d8905565793f7a2ff5877ddbd788b50098248c8
+DIST eid-mw-5.1.23.tar.gz 16302987 BLAKE2B 25c22aaa204839976c2ea9a9dae00fe88853b8278e01b58164c4c860c12f8ff97c8d370e74bc6cb4b6784f71c04642aa9e3dde447671747070a5a552f0a964d4 SHA512 ad79b1b83dbd38b95d67cf312cdf8de70c5c49922d69ea318e9e14999f4797c8a11f9b0db6febd98452151bc6145e30f2f0089d663138b664d11b140621a481d

app-crypt/eid-mw/eid-mw-5.1.23.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop gnome2-utils
+
+DESCRIPTION="Electronic Identity Card middleware supplied by the Belgian Federal Government"
+HOMEPAGE="https://eid.belgium.be"
+SRC_URI="https://codeload.github.com/fedict/${PN}/tar.gz/v${PV} -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+dialogs +gtk p11-kit"
+
+RDEPEND="sys-apps/pcsc-lite
+	gtk? (
+		x11-libs/gdk-pixbuf[jpeg]
+		x11-libs/gtk+:3
+		dev-libs/libxml2:=
+		net-misc/curl[ssl]
+		net-libs/libproxy
+		app-crypt/pinentry[gtk]
+	)
+	p11-kit? ( app-crypt/p11-kit )"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="dialogs? ( gtk )"
+
+PATCHES=(
+	"${FILESDIR}/0001-Do-not-build-xpi-module.patch"
+	"${FILESDIR}/0001-Fix-libdir-for-manifestdir.patch"
+	"${FILESDIR}/0001-Remove-uml-build.patch"
+	)
+
+src_prepare() {
+	default
+
+	# Buggy internal versioning when autoreconf a tarball release.
+	# Weird numbering is required otherwise we get a seg fault in
+	# about-eid-mw program.
+	echo "${PV}-v${PV}" > .version
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable dialogs) \
+		$(use_enable p11-kit p11kit) \
+		$(use_with gtk gtkvers '3') \
+		--with-gnu-ld
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+	if use gtk; then
+		domenu plugins_tools/eid-viewer/eid-viewer.desktop
+		doicon plugins_tools/eid-viewer/gtk/eid-viewer.png
+	fi
+}
+
+pkg_postinst() {
+	if use gtk; then
+		gnome2_schemas_update
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+
+		local peimpl=$(eselect --brief --colour=no pinentry show)
+		case "${peimpl}" in
+		*gnome*|*qt*) ;;
+		*)	ewarn "The pinentry front-end currently selected is not supported by eid-mw."
+			ewarn "You may be prompted for your pin code in an inaccessible shell!!"
+			ewarn "Please select pinentry-gnome3 as default pinentry provider:"
+			ewarn " # eselect pinentry set pinentry-gnome3"
+		;;
+		esac
+	fi
+}
+
+pkg_postrm() {
+	if use gtk; then
+		gnome2_schemas_update
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}