gnome-extra/nm-applet: Bump to 1.8.22

Closes: https://bugs.gentoo.org/687370
Package-Manager: Portage-2.3.67, Repoman-2.3.13
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

gnome-extra/nm-applet/Manifest

@@ -1 +1,2 @@
 DIST network-manager-applet-1.8.20.tar.xz 1551392 BLAKE2B 91258012715f226467126e4eefdfcd6ebde36958be80ae5e264dbf5168e0b772ce04404030d3f7dac9a6f72088918a2c5160aba694b6b7f7d4d6289b716b76f1 SHA512 5020aefe1803ad3b59562478e793737b52a3e5fd294470cfb430c73937cdbc0be6ecba5f3f8e8dbcc5bb5ac293df2866ecc919dd5019a3e681a434078d235a41
+DIST network-manager-applet-1.8.22.tar.xz 2058500 BLAKE2B e4b31ea3dfe91f07a61b7dd4c34521bc4fc2d7a1b7e5649690336cce0c425d57128ff8011b18a6505893982bfd81170eb8239b9e83de6f91afa11190cfac3b4d SHA512 d2f679a67b79b011762f9249798c5a4ccad3d0fdd01d8d45956a65ab75398ccc07167fc5452748a12294315f729b10115edcb9f11e05475bb0b15b2ade638dd3

gnome-extra/nm-applet/nm-applet-1.8.22.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+GNOME_ORG_MODULE="network-manager-applet"
+
+inherit gnome2
+
+DESCRIPTION="GNOME applet for NetworkManager"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="ayatana +introspection +gcr +modemmanager selinux teamd"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=app-crypt/libsecret-0.18
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/dbus-glib-0.88
+	>=sys-apps/dbus-1.4.1
+	>=sys-auth/polkit-0.96-r1
+	>=x11-libs/gtk+-3.10:3[introspection?]
+	>=x11-libs/libnotify-0.7.0
+
+	app-text/iso-codes
+	>=net-misc/networkmanager-1.7:=[introspection?,modemmanager?,teamd?]
+	net-misc/mobile-broadband-provider-info
+
+	ayatana? (
+		dev-libs/libappindicator:3
+		>=dev-libs/libdbusmenu-16.04.0 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	virtual/freedesktop-icon-theme
+	virtual/libgudev:=
+	gcr? ( >=app-crypt/gcr-3.14:=[gtk] )
+	modemmanager? ( net-misc/modemmanager )
+	selinux? ( sys-libs/libselinux )
+	teamd? ( >=dev-libs/jansson-2.7 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.0
+	>=dev-util/intltool-0.50.1
+	virtual/pkgconfig
+"
+
+PDEPEND="virtual/notification-daemon" #546134
+
+src_configure() {
+	local myconf=(
+		--with-appindicator=$(usex ayatana ubuntu no)
+		--with-libnm-gtk
+		--disable-lto
+		--disable-ld-gc
+		--disable-more-warnings
+		--disable-static
+		--localstatedir=/var
+		$(use_enable introspection)
+		$(use_with gcr)
+		$(use_with modemmanager wwan)
+		$(use_with selinux)
+		$(use_with teamd team)
+	)
+	gnome2_src_configure "${myconf[@]}"
+}