dev-python/stripe: Version bumps

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Cédric Krier <cedk@gentoo.org>

dev-python/stripe/Manifest

@@ -1 +1,2 @@
 DIST stripe-2.43.0.tar.gz 211400 BLAKE2B 135371f793af291e1c43179bcb325a9eb84c3258d9013009f920077fbc783569b6384fa76dcf464aa9fdbe64a4a297d6c232f3719729a81e1d62c74b769ff5f7 SHA512 a91f4f268b5c533cdd378c3169cf6e29b11b3b79492cd8b01b21970459383d63fa726fb206aba111ef8e57c2b98eecd6ba3ef9fdb868efc2db69f0cba8f74554
+DIST stripe-2.46.0.tar.gz 218080 BLAKE2B 990535efd32b5ddfe166d5b6ad1cdcd966df53fe830a10938355cac10287542284a73f99332878225388a3c28ba431baf96fa4e6e745345c9fa02e64a7e33c0f SHA512 dbfa586cfe7897b32fe95b7230fca5ccb8a12b429982776ee8873878fb6b7284cbb924e8dc6031d59647cc6080115ad541fda02d320c091b6c1bb374679d2213

dev-python/stripe/stripe-2.46.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Stripe python bindings"
+HOMEPAGE="https://github.com/stripe/stripe-python"
+SRC_URI="mirror://pypi/s/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+"
+# See https://github.com/stripe/stripe-python/blob/v2.10.1/tests/conftest.py#L17
+# for minimum required version of stripe-mock
+# Running the tests against dev-util/stripe-mock-0.47.0 resulted in test errors
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-util/stripe-mock-0.88.0
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		net-misc/curl
+	)
+"
+
+DOCS=(LONG_DESCRIPTION.rst CHANGELOG.md README.md)
+
+src_test() {
+	local stripe_mock_port=12111
+	local stripe_mock_max_port=12121
+	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
+	# Try to start stripe-mock until we find a free port
+	while [[ "${stripe_mock_port}" -le "${stripe_mock_max_port}" ]]; do
+		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
+		stripe-mock --http-port ${stripe_mock_port} &> "${stripe_mock_logfile}" &
+		local stripe_mock_pid=$!
+		sleep 2
+		# Did stripe-mock start?
+		curl --fail -u "sk_test_123:" \
+			http://127.0.0.1:${stripe_mock_port}/v1/customers &> /dev/null
+		eend $? "Port ${stripe_mock_port} unavailable"
+		if [[ $? -eq 0 ]]; then
+			einfo "stripe-mock running on port ${stripe_mock_port}"
+			break
+		fi
+		(( stripe_mock_port++ ))
+	done
+	if [[ "${stripe_mock_port}" -gt "${stripe_mock_max_port}" ]]; then
+		eerror "Unable to start stripe-mock for tests"
+		die "Please see the logfile located at: ${stripe_mock_logfile}"
+	fi
+
+	distutils-r1_src_test
+
+	# Tear down stripe-mock
+	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
+}
+
+python_test() {
+	STRIPE_MOCK_PORT=${stripe_mock_port} pytest -vv || die "Tests failed with ${EPYTHON}"
+}