dev-python/spur: New package, test-dep of dev-python/locket

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/spur/Manifest

@@ -0,0 +1 @@
+DIST spur.py-0.3.21.gh.tar.gz 17666 BLAKE2B 0628417e6b5f4c744041693445113a59daac4f89776bc39849a2e1fab21826f3c6783bf72bf528a262f05df08d0680044e69f119c367f29ca4d6f0df554fa49d SHA512 7cd49690b989952707629fad5682201dc7f00865d8120da9e84eb9046e7a8fe7b7183785b4c2eac996d2743025cc09508b0ceb7b762b7bddb5447ecbc42d00a4

dev-python/spur/metadata.xml

@@ -0,0 +1,7 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+</pkgmetadata>

dev-python/spur/spur-0.3.21.ebuild

@@ -0,0 +1,36 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit distutils-r1
+
+MY_P=spur.py-${PV}
+DESCRIPTION="Run commands locally or over SSH using the same interface"
+HOMEPAGE="https://github.com/mwilliamson/spur.py"
+SRC_URI="
+	https://github.com/mwilliamson/spur.py/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+distutils_enable_tests nose
+
+src_prepare() {
+	# TODO: set up a local SSH server?
+	rm tests/{ssh_tests,testing}.py || die
+
+	# does random guesswork on top of exceptions that stopped working
+	# in py3.8;  this only causes a different exception to be raised
+	# https://github.com/mwilliamson/spur.py/issues/85
+	sed -e 's:spawning_command_that_uses_path_env_variable_asks_if_command_is_installed:_&:' \
+		-e 's:spawning_non_existent_command_raises_specific_no_such_command_exception:_&:' \
+		-e 's:using_non_existent_command_and_correct_cwd_raises_no_such_command_exception:_&:' \
+		-i tests/process_test_set.py || die
+
+	distutils-r1_src_prepare
+}