media-video/mkvtoolnix: version bump to 17.0.0

This commit is contained in:
Tim Harder
2017-10-16 20:33:52 -04:00
parent a413d95d80
commit a1fac8a73f
2 changed files with 111 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST mkvtoolnix-15.0.0.tar.xz 4552588 SHA256 73dc3b6f0a7147e28c06f44427fa0e824d0a4129e40c942d7642d9f451a51195 SHA512 5cef57dce4e6ca3d036142e42e302e8a315782ded11fb4c5982b406d389c8709bc7cf2a86d605b7c02797dc7b907dc3895db515e9d3e40976ab14198d9f400c6 WHIRLPOOL ee4bb153c4773535526bcb7352c13eab84a8b7fa28e66862f5bdc931a89e5ba3fc0d4c621f6784a9bd8b3a35c95cd1c1fdae9cfbb85640077b81b0914dc96fa5
DIST mkvtoolnix-16.0.0.tar.xz 4607360 SHA256 5dfb2517003f69f3d8b942751200122c2e4cad2a8675b6fc2dfaad5c98e946e0 SHA512 5255c5a1d995bbf24d414dcdde8de987295581d4a8054164f15dca6019c79d96c9c074dc1892a86cd0084da34079529357efbeb3381addd9dc087b433be493fa WHIRLPOOL 20c2c2b387f78a5c2486692dda1503016447a551cd97d831b551c83e58ebecbf787deaca75d31b0409544eb11d354f2eb21b6585bb21fb30499c91c9af33f4d1
DIST mkvtoolnix-17.0.0.tar.xz 4606064 SHA256 9faf7996b84eb68c2b1738ec27217d24480731b24d31c81fbef19daa5844992e SHA512 9d092949a78bcf063483219245b610c73b73dd6c3bb740e4c30016c49dd35612629679df10265235ad1e7f77422afa913ae9473765611b049eef6d8f2f174fe5 WHIRLPOOL 8339b68f449f3275a49c5276def399f4b2156cf890f6cc77c88f501ae3c127d4f12b57c623b9818cad0ab5985d701bad1927c32c7f0a55e8012b209631d00421
DIST mkvtoolnix-9.6.0.tar.xz 3810216 SHA256 ebab8dcc59533d248b127d375286eb47880a222ef68ff7a10e1c87d49dbd86bb SHA512 5f469215a10dc865e51f77c43961705d70b1b0e38d70b930e5065d8d89b8379734d9826a63e2cb7ae9cb6723ed8a1d16793df35bad6244cedaa19bc4df49b436 WHIRLPOOL f90056b595402315651754bf4428762a99a665f8ce78d7eb8d6d5ad3bb8bc95e19b130c154c52c2d1281028ebf78c5834abedf068601382a3fcca9ea2c37aa2a
@@ -0,0 +1,110 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit toolchain-funcs versionator multiprocessing
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="https://github.com/mbunkus/mkvtoolnix.git"
inherit git-r3
else
SRC_URI="https://mkvtoolnix.download/sources/${P}.tar.xz"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
fi
DESCRIPTION="Tools to create, alter, and inspect Matroska files"
HOMEPAGE="https://mkvtoolnix.download/ https://github.com/mbunkus/mkvtoolnix"
LICENSE="GPL-2"
SLOT="0"
IUSE="debug pch test qt5"
# check NEWS.md for build system changes entries for boost/libebml/libmatroska
# version requirement updates and other packaging info
RDEPEND="
>=dev-libs/boost-1.49.0:=
>=dev-libs/libebml-1.3.5:=
dev-libs/jsoncpp:=
dev-libs/pugixml
media-libs/flac
>=media-libs/libmatroska-1.4.8:=
media-libs/libogg
media-libs/libvorbis
sys-apps/file
sys-libs/zlib
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
dev-qt/qtconcurrent:5
dev-qt/qtmultimedia:5
)
"
DEPEND="${RDEPEND}
dev-ruby/rake
sys-devel/gettext
virtual/pkgconfig
dev-libs/libxslt
app-text/docbook-xsl-stylesheets
app-text/po4a
test? ( dev-cpp/gtest )
"
DOCS="AUTHORS NEWS.md README.md"
pkg_pretend() {
# https://bugs.gentoo.org/419257
local ver=4.6
local msg="You need at least GCC ${ver}.x for C++11 range-based 'for' and nullptr support."
if ! version_is_at_least ${ver} $(gcc-version); then
eerror ${msg}
die ${msg}
fi
}
src_prepare() {
default
[[ ${PV} == "9999" ]] && { ./autogen.sh || die; }
}
src_configure() {
local myconf
if use qt5 ; then
# ac/qt5.m4 finds default Qt version set by qtchooser, bug #532600
myconf+=(
--with-moc=/usr/$(get_libdir)/qt5/bin/moc
--with-uic=/usr/$(get_libdir)/qt5/bin/uic
--with-rcc=/usr/$(get_libdir)/qt5/bin/rcc
--with-qmake=/usr/$(get_libdir)/qt5/bin/qmake
)
fi
econf \
$(use_enable debug) \
$(use_enable qt5 qt) \
$(usex pch "" --disable-precompiled-headers) \
"${myconf[@]}" \
--disable-update-check \
--disable-optimization \
--docdir="${EPREFIX}"/usr/share/doc/${PF} \
--with-boost="${EPREFIX}"/usr \
--with-boost-libdir="${EPREFIX}"/usr/$(get_libdir)
}
src_compile() {
rake V=1 -j$(makeopts_jobs) || die
}
src_test() {
rake V=1 -j$(makeopts_jobs) tests:unit || die
rake V=1 -j$(makeopts_jobs) tests:run_unit || die
}
src_install() {
DESTDIR="${D}" rake -j$(makeopts_jobs) install || die
einstalldocs
doman doc/man/*.1
}