net-libs/libktorrent: 25.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-libs/libktorrent/Manifest

@@ -1 +1,2 @@
 DIST libktorrent-24.12.3.tar.xz 604656 BLAKE2B e41bb0a7b53eddd478d86b2ac87c65ae4ac4754cee1d398a0ef647acd3a71342db8d667b9cf5a936eeafbacb4e593bab30dd310bec2632cc43aea21f4d390bb3 SHA512 52025e7fe6515f02545b26450b85bb3d5111391a471241dce73f8ec300512da90261f257672d38b9b73d104f1dba8b107aef8890a13ddb70970482f0c1b31bf7
+DIST libktorrent-25.04.0.tar.xz 606316 BLAKE2B aac0463ddf1f5d367bf5e8a501722ba6701a41f3de8056fe449b06176fbf5e4da5166d08113eb3c18883e1567d8446fe3ae33603c89c7d68bf8206ef8032c2c9 SHA512 deb21d8c8f2cd72735e5d718008d383e5ac44a8aa4b11c326b9cf8479e8a8f1b38d1e905b9ae36ca902289428444f09e0d0c5f421ee7a00622da336b748ceda4

net-libs/libktorrent/libktorrent-25.04.0.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KDE_ORG_CATEGORY="network"
+KFMIN=6.9.0
+QTMIN=6.7.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="BitTorrent library based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/ https://userbase.kde.org/KTorrent"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="xfs"
+
+COMMON_DEPEND="
+	>=app-crypt/qca-2.3.7:2[qt6(+)]
+	>=dev-libs/gmp-6.0.0a:0=
+	dev-libs/libgcrypt:0=
+	>=dev-qt/qtbase-${QTMIN}:6[network,xml]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	xfs? ( sys-fs/xfsprogs )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	!dev-libs/botan[gmp(-)]
+"
+BDEPEND="sys-devel/gettext"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
+	sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
+		CMakeLists.txt || die
+	sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
+		KTorrent6Config.cmake.in || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_XFS=$(usex xfs)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# failing network tests
+	local myctestargs=(
+		-E "(fin|packetloss|send|superseedtest|transmit|utppolltest)"
+	)
+	ecm_src_test
+}