app-crypt/signing-party: add 2.12

Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
2026-02-05 21:22:06 +00:00
parent 015632b4dd
commit a1a3d4ae53
2 changed files with 122 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST signing-party_2.11.orig.tar.gz 224706 BLAKE2B 6ef03d9e7e5652b7da77facc3206d25de63958a56ef64c0393b9964e1653c099dc022be5c80a02041418aee9dcb74e4fc0c448198b1deade79e59372cb8308c0 SHA512 9a34bde415bf779859b48eaab12e5c6a1a3f08d0292cd5cd691518e398fe40a73b878926d3ea1ef12ccca40179933478d03ec16ec4d9200fb726aaade541505d
DIST signing-party_2.12.orig.tar.gz 225063 BLAKE2B d2e81da6d97f223ea48d8e0bf82ee2b3dc03e79b2347d7b613ede0951025ecd831bf4c52ed396b0236b94c50203c9f1ae87a64c2719072742b23ab72c7184a77 SHA512 c1c41766dfe36e54fe51f8127a3e190ca97539718aa1ebb87409429193908ad6deea6fd296433bbaf030cb83330e86e1e109e7ae3626e985bf0c4c388ce1538e
@@ -0,0 +1,121 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools toolchain-funcs
DESCRIPTION="Collection of several tools related to OpenPGP"
HOMEPAGE="https://salsa.debian.org/signing-party-team/signing-party"
SRC_URI="mirror://debian/pool/main/s/signing-party/${PN}_${PV}.orig.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
DEPEND="
app-crypt/libmd
"
RDEPEND="
${DEPEND}
|| ( >=app-crypt/gnupg-1.3.92 app-crypt/freepg )
dev-perl/GnuPG-Interface
dev-perl/Text-Template
dev-perl/MIME-tools
>=dev-perl/MailTools-1.62
dev-perl/Net-IDN-Encode
net-mail/qprint
virtual/mailx
virtual/mta
|| (
dev-perl/libintl-perl
dev-perl/Text-Iconv
app-text/recode
)
"
BDEPEND="
dev-lang/perl
"
src_prepare() {
default
# app-crypt/keylookup
rm -r keylookup || die
sed -i -e 's#keylookup/keylookup##' Makefile || die
# media-gfx/springgraph
rm -r springgraph || die
find . -name Makefile | xargs sed -i -e 's/CFLAGS:=/CFLAGS=/' -e 's/CPPFLAGS:=/CPPFLAGS=/' -e 's/LDFLAGS:=/LDFLAGS=/'
sed -i -e 's/autoreconf/true/g' keyanalyze/Makefile || die
pushd keyanalyze/pgpring || die
eautoreconf
popd || die
}
src_compile() {
emake \
CC="$(tc-getCC)" \
CPPFLAGS="${CPPFLAGS}" \
CFLAGS="${CFLAGS}" \
LDFLAGS="${LDFLAGS}" \
STRIP=true
}
src_install() {
einstalldocs
# Check Makefile when a new tool is introduced to this package.
# caff
dobin caff/caff caff/pgp-clean caff/pgp-fixkey
docinto caff
dodoc caff/{README*,THANKS,TODO,caffrc.sample}
# gpgdir
dobin gpgdir/gpgdir
docinto gpgdir
dodoc gpgdir/{VERSION,LICENSE,README,INSTALL,CREDITS,ChangeLog*}
# gpg-key2ps
dobin gpg-key2ps/gpg-key2ps
docinto gpg-key2ps
dodoc gpg-key2ps/README
# gpglist
dobin gpglist/gpglist
# gpg-mailkeys
dobin gpg-mailkeys/gpg-mailkeys
docinto gpg-mailkeys
dodoc gpg-mailkeys/{example.gpg-mailkeysrc,README}
# gpgparticipants
dobin gpgparticipants/gpgparticipants
# gpgwrap
dobin gpgwrap/bin/gpgwrap
docinto gpgwrap
dodoc gpgwrap/{LICENSE,NEWS,README}
doman gpgwrap/doc/gpgwrap.1
# gpgsigs
dobin gpgsigs/gpgsigs
insinto /usr/share/signing-party
# keyanalyze
# TODO: some of the scripts are intended for webpages, and not really
# packaging, so they are NOT installed yet.
newbin keyanalyze/pgpring/pgpring pgpring-keyanalyze
dobin keyanalyze/{keyanalyze,process_keys}
docinto keyanalyze
dodoc keyanalyze/{README,Changelog}
# See app-crypt/keylookup instead
#dobin keylookup/keylookup
#docinto keylookup
#dodoc keylookup/NEWS
# sig2dot
dobin sig2dot/sig2dot
dodoc sig2dot/README.sig2dot
# gog-key2latex
dobin gpg-key2latex/gpg-key2latex
# See media-gfx/springgraph instead
#dobin springgraph/springgraph
#dodoc springgraph/README.springgraph
# all other manpages, and the root doc
doman */*.1
dodoc README
}