app-forensics/aide: add 0.18.8

Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Michael Mair-Keimberger
2024-06-14 13:36:41 +03:00
committed by Arthur Zamarin
parent 9d179f221c
commit a1937adca7
2 changed files with 107 additions and 0 deletions
+1
View File
@@ -2,4 +2,5 @@ DIST aide-0.17.4.tar.gz 331783 BLAKE2B 584a385d0a0e80edf0b89eef202431adfea7fe8ba
DIST aide-0.18.2.tar.gz 382582 BLAKE2B 267233a4dfdbc5a433389c20a1abe753133dfa01ecc205769c89a9b4699535b1d00e9df6527ae8298f4cb920e2f755e4d75d17b4a2449041a85c8c5e5ecc2abc SHA512 3a209db9dc1adb345494ce20a5c3def9f40ae49723d3a978d8e9b38f43239496a330b484ed93adba88154770ce1f1a0f3cdeb2ff8d991d28a1d66cfa6cd9b68b
DIST aide-0.18.3.tar.gz 382694 BLAKE2B f5e79d80c1fa2ba15096d38c1a1d197fc8665bc0ff03665367abce7722561f2054cc64f51429a1411d6aaa0df315869ac99314e660acdff31bf1dc6b471a62b8 SHA512 22f1d2d3e14fa88639587f5a61e114b89c784a87f636c1bbb245e620254b60ec07692e51ae27386a84810d7a915e0ddf5c5073fecb6eb72148ff5035ef8525eb
DIST aide-0.18.4.tar.gz 382874 BLAKE2B e8fe8a115236f055f24b907ddcf540f02658b85c1df99ff9a8f58dfa9489de3d542b25bb947e047c8363c81d1f0ad0730fd77efacabe15fa24bbafc3fd807687 SHA512 31a17fc97ed9bda5dc4a492bcee699442cee1ea3829b1b06cf91ef9234a8b033677c281979902cbc6a8db0269c7f00499897940df07beff14cbb88b8fe6390f5
DIST aide-0.18.8.tar.gz 383589 BLAKE2B a3b7efca89d0be99614e423a983fb0a3413f1cbdbc370b54f755e6dae8bb7f5612921ba998fd6db9248ae739fdaf3d344e092933b7dad7fd94dc1844e68a605e SHA512 38763f527cfbc11847eca2fca17eceabc46158624954f0457feb49b885f34e4311f2dbc50b5471f4ff972e9e4e9c9f55c2da8dd8d55c04063a9043ab4829ff05
DIST aide-0.18.tar.gz 375922 BLAKE2B 03c961682fd25581831ca0715e57546b5595057115a456778ac0846fd1f23622600a061e2d8524f7381dfa6d43cefcdaa52d00eed2639dd60c7f3501efe8b474 SHA512 99d8140523ebe1d80b5d73c20bf13b8559aa22f08a9df485c15daeba7f5448c27d86ed310f2e7963076958dbe1fc2e4636807ca073dd0a6568b4eb8af2a38f4b
+106
View File
@@ -0,0 +1,106 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit readme.gentoo-r1
DESCRIPTION="AIDE (Advanced Intrusion Detection Environment) is a file integrity checker"
HOMEPAGE="https://aide.github.io/ https://github.com/aide/aide"
SRC_URI="https://github.com/aide/aide/releases/download/v${PV}/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="acl audit curl e2fs mhash selinux xattr"
DEPEND="
dev-libs/libpcre2
sys-libs/zlib
acl? ( virtual/acl )
audit? ( sys-process/audit )
curl? ( net-misc/curl )
e2fs? ( sys-fs/e2fsprogs )
!mhash? (
dev-libs/libgcrypt:=
dev-libs/libgpg-error
)
mhash? ( app-crypt/mhash )
selinux? ( sys-libs/libselinux )
xattr? ( sys-apps/attr )
"
RDEPEND="
${DEPEND}
selinux? ( sec-policy/selinux-aide )
"
BDEPEND="
sys-devel/bison
sys-devel/flex
virtual/pkgconfig
"
DISABLE_AUTOFORMATTING=1
DOC_CONTENTS="
Example configuration file was installed at '${EPREFIX}/etc/aide/aide.conf'.
Please edit it to meet your needs. Refer to aide.conf(5) manual page
for more information.
A helper script, aideinit, was installed and can be used to make AIDE
management easier. Please run 'aideinit --help' for more information."
src_prepare() {
default
# Only needed for snapshots.
if [[ ${PV} == *_p* ]] ; then
echo "m4_define([AIDE_VERSION], [${PV}])" > version.m4 || die
fi
}
src_configure() {
# Needs Bison, flex
unset YACC
export LEX=flex
local myeconfargs=(
--sysconfdir="${EPREFIX}"/etc/${PN}
# Needed even in EAPI=8, >=portage-3.0.40 skips it here (bug #887177)
--disable-static
# Disable broken l10n support: https://sourceforge.net/p/aide/bugs/98/
# This doesn't affect anything because there are no localizations yet.
--without-locale
--with-zlib
$(use_with curl)
$(use_with acl posix-acl)
$(use_with selinux)
$(use_with xattr)
$(use_with e2fs e2fsattrs)
$(use_with mhash mhash)
$(use_with !mhash gcrypt)
$(use_with audit)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
readme.gentoo_create_doc
insinto /etc/${PN}
insopts -m0600
newins "${FILESDIR}"/aide.conf-r2 aide.conf
dosbin "${FILESDIR}"/aideinit
dodoc -r contrib/ "${FILESDIR}"/aide.cron-r2
keepdir /var/{lib,log}/${PN}
}
pkg_postinst() {
readme.gentoo_print_elog
}