app-i18n/opencc: Version bump (1.1.4)

Signed-off-by: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>
Signed-off-by: Yixun Lan <dlan@gentoo.org>

app-i18n/opencc/Manifest

@@ -1 +1,2 @@
 DIST opencc-1.1.3.tar.gz 2805430 BLAKE2B 060ca820676a92ddfddc362488031e1ada538626a1fbeb8d178a0ef059b99f606cb0f1151857579221942183820bf34c6f96517d13d4ae8dc3f81846537b668d SHA512 90da656fa4790c58932ad2240a076cc4a9e8cf70ac73d83e0d299e84472deb6491a823966a7686ed1487ef8405909981b9a12b661d8de7f086bd4b498594abac
+DIST opencc-1.1.4.tar.gz 2806887 BLAKE2B 150fd83818616de42e535f349b2574ff3319e41618e522583a57a00ab08b7f28db6e8f4fa4a0d4dbe027753b5be87065b2015542251986c6301ad441c4bf4c98 SHA512 ab8e7e6a0cc71106cf09eb32899fa8620b946a406f042d75a2444096e0b383cb1993d6c2d12cd7862e71854da4cd5893442bce51df84c32ed09fdfb4a2846f46

app-i18n/opencc/opencc-1.1.4.ebuild

@@ -0,0 +1,69 @@
+# Copyright 2010-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake python-any-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/BYVoid/OpenCC"
+fi
+
+DESCRIPTION="Library for conversion between Traditional and Simplified Chinese characters"
+HOMEPAGE="https://github.com/BYVoid/OpenCC"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/BYVoid/OpenCC/archive/ver.${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0/1.1"
+KEYWORDS="~amd64 ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="${PYTHON_DEPS}
+	doc? ( app-doc/doxygen )"
+DEPEND="dev-cpp/tclap
+	dev-libs/darts
+	dev-libs/marisa:0=
+	dev-libs/rapidjson
+	test? (
+		dev-cpp/gtest
+		!hppa? ( !sparc? ( dev-cpp/benchmark ) )
+	)"
+RDEPEND="dev-libs/marisa:0="
+
+if [[ "${PV}" != "9999" ]]; then
+	S="${WORKDIR}/OpenCC-ver.${PV}"
+fi
+
+DOCS=(AUTHORS NEWS.md README.md)
+
+src_prepare() {
+	rm -r deps || die
+
+	cmake_src_prepare
+
+	sed -e "s:\${DIR_SHARE_OPENCC}/doc:share/doc/${PF}:" -i doc/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc ON OFF)
+		-DENABLE_BENCHMARK=$(if use test && has_version -d dev-cpp/benchmark; then echo ON; else echo OFF; fi)
+		-DENABLE_GTEST=$(usex test ON OFF)
+		-DUSE_SYSTEM_DARTS=ON
+		-DUSE_SYSTEM_GOOGLE_BENCHMARK=ON
+		-DUSE_SYSTEM_GTEST=ON
+		-DUSE_SYSTEM_MARISA=ON
+		-DUSE_SYSTEM_RAPIDJSON=ON
+		-DUSE_SYSTEM_TCLAP=ON
+	)
+
+	cmake_src_configure
+}