dev-python/oslo-concurrency: Bump to 5.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/oslo-concurrency/Manifest

@@ -1 +1,2 @@
 DIST oslo.concurrency-5.0.1.tar.gz 59944 BLAKE2B 76962f187d58c514f7465a5cac2e695ee83ca020ae0f9d0d0d5a8e27cfcfb6d008f2df97f8b353ef2e7c57562b2cd169a4f6ccfb16bdaefcce1ace81445a64a7 SHA512 5987900e71020b2b8b77eac69c3541647c1600cb8a51f02d45938367e45ddce5e71b874a1eda79aadfec51d639fdb895f056964d0b4bd9bba597ae9423f35463
+DIST oslo.concurrency-5.1.0.tar.gz 59835 BLAKE2B feda58a724e835c060667edf7c126ac0a26c62dace84db5e0909abbecc3dd5649aca791e084e218bd39d2463ed4fe878a4a16018483191cf3668df8eb7761859 SHA512 a4fac20c32cff9c30cd464631cc4d390626ea4a52bfd5c132808983e682d32fe61cf7a735b01b85c4be806c6f473efc1ed89bfa42211a7ff59215d35cd607c77

dev-python/oslo-concurrency/oslo-concurrency-5.1.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Oslo Concurrency library"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.concurrency/
+	https://github.com/openstack/oslo.concurrency/
+	https://pypi.org/project/oslo.concurrency/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# fails, then hangs
+	rm oslo_concurrency/tests/unit/test_lockutils_eventlet.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest
+}