dev-python/translate-toolkit: Bump to 3.7.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1,2 +1,3 @@
 DIST translate-3.6.2.gh.tar.gz 1152569 BLAKE2B 44c9a5878a177b53d34e48d8b642f293ed475c90de8a530f53462384420b8afaaf107cb62c0cdd45e6d0633f53cd8eedb73dd0dcd81d6f876dc5389ba4230c94 SHA512 fb1fc2f6abb766814269d7051f571cbfb25ecd6b7267e2080e5ab0bb41338ace430a8bb01084abe176e2fd0a934cdf6492bf79f5e27c1f8ce99b021175efcec9
 DIST translate-3.7.0.gh.tar.gz 1152162 BLAKE2B 75d3b0a7f2a840766f983d6e1484aab16de2aa2bab74d0753910be9ad0d1c76ebfa553188318920a7d5a6f1ce6b72e755147eb45c501cdeb79246472c0329449 SHA512 18159f85d94768c32fe5a44f3d3e586038b281a0f3e386621bd57a5be64a9ae21a4272c05de8a2ea2a2467c98935205a8ef49a714dc9aabf9ed21de4f533fb93
+DIST translate-3.7.1.gh.tar.gz 1152674 BLAKE2B c4a7d8cb1eec656a261a1af145a1171e9d686348294a0849f29ae23dcd867d831c6f95f0927101325f62ef9b21e0891a7a574f08111bbc3e9c0ce2b996faa70c SHA512 5ed9d156f071f4ce567a0ff3f0ef5c0b42b312edaae82e96eee040ae9547f0cb3334f2973d8050b9181b752f7e81021cc183613bb5c6309aeb110bcacab212fb

dev-python/translate-toolkit/translate-toolkit-3.7.1.ebuild

@@ -0,0 +1,99 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-bootstrap-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		translate/storage/test_fluent.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}