dev-python/fonttools: Bump to 4.49.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-02-16 06:40:12 +01:00
parent a52d9a5dee
commit a0b69ce91b
2 changed files with 99 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST fonttools-4.47.2.gh.tar.gz 3813471 BLAKE2B 7c478395e1c0cad52a29bc504bac235c4e198284a7f1f4b32e9db0704d3eeb56ea69d563a862239396fd1e67f47f168ae2f42676fe5ba3f9e1c356de8c5039f2 SHA512 03b6411c72ce38eeaa6401440d9612a37cd2ff6a686d7c6dbe7328a876f9e4369c06edea184ea72c1002b26b956d0196c241e40fe28b0ccf42f616ce9a700a07
DIST fonttools-4.48.1.gh.tar.gz 3815962 BLAKE2B 86f93ddfbff0d3e5e165adc73908176ec3eee1d35d7009faa9827bc992d6bb5a11b95823596ae40ea739b117af7933fea0b768cf3a44d4cb770daa7db42048c9 SHA512 1f8336880575038f904873f6359b9c0a5885f14358c5560592b274db7aa2b96433770f5195e93ac04552f2580aadf0efc9268dcce9f0d178b78e75f5507dad67
DIST fonttools-4.49.0.gh.tar.gz 3818768 BLAKE2B add7c03762e6c09950f2abfb8b19e627f7ce367b73c48b02059ab308ee7f8475e94c575719a168166497261cb4762ec4959c7812ab5fc122477a7751a8fabdb9 SHA512 6caa108b92a9661f6761a4e1c65f05cabf0d4f6a6f2517d2a289afc5e60ad73c7e35ee283d1a206b1bcd2ec5861f70272e323b9041aa949c713dc531d2d056d2
@@ -0,0 +1,98 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3 python3_{10..12} )
PYTHON_REQ_USE="xml(+)"
inherit distutils-r1 virtualx
DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
HOMEPAGE="
https://github.com/fonttools/fonttools/
https://pypi.org/project/fonttools/
"
SRC_URI="
https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
IUSE="+native-extensions"
RDEPEND="
>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
"
BDEPEND="
native-extensions? (
$(python_gen_cond_dep '
dev-python/cython[${PYTHON_USEDEP}]
' 'python*')
)
test? (
dev-python/brotlicffi[${PYTHON_USEDEP}]
dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
app-arch/zopfli
)
"
EPYTEST_XDIST=1
distutils_enable_tests pytest
python_prepare_all() {
# When dev-python/pytest-shutil is installed, we get weird import errors.
# This is due to incomplete nesting in the Tests/ tree:
#
# Tests/feaLib/__init__.py
# Tests/ufoLib/__init__.py
# Tests/svgLib/path/__init__.py
# Tests/otlLib/__init__.py
# Tests/varLib/__init__.py
#
# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
touch Tests/svgLib/__init__.py || die
distutils-r1_python_prepare_all
}
python_compile() {
local -x FONTTOOLS_WITH_CYTHON=$(usex native-extensions)
[[ ${EPYTHON} == pypy3 ]] && FONTTOOLS_WITH_CYTHON=0
distutils-r1_python_compile
}
src_test() {
# virtualx used when matplotlib is installed causing plot module tests to run
virtx distutils-r1_src_test
}
python_test() {
local EPYTEST_DESELECT=(
# flaky test
Tests/ttLib/woff2_test.py::WOFF2ReaderTest::test_get_normal_tables
)
if [[ ${EPYTHON} == pypy3 ]] &&
has_version "dev-python/pyxattr[${PYTHON_USEDEP}]" &&
{
has_version "<dev-python/pypy3_10-exe-7.3.13_p2" ||
has_version "<dev-python/pypy3_10-exe-bin-7.3.13_p2"
}
then
EPYTEST_DESELECT+=(
# affected by a bug in PyPy/pyxattr
# https://github.com/iustin/pyxattr/issues/41
Tests/t1Lib/t1Lib_test.py::ReadWriteTest::test_read_with_path
)
fi
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
nonfatal epytest \
-p rerunfailures --reruns=5 \
Tests fontTools || die -n "Tests failed with ${EPYTHON}"
}