dev-python/trio: Add 0.25.1_p20240613 snapshot with py3.13

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/trio/Manifest

@@ -1 +1,2 @@
 DIST trio-0.25.1.gh.tar.gz 600963 BLAKE2B f72df0069ff48f198f7c31221c721ffb127c4cac6c4e004547d62aa5f184673fde09e2baad5c383b206deffec4ef1b04dafad883dad0b2ced2625d72ac842887 SHA512 0a924a1c52ed5153e51cc3343c92b7f6218cf8c56ba2e66b6fe40d27d2acfa7475c3014b8fc5fd22e46df1782530a75f899dbb35d1c875331400957891bd70aa
+DIST trio-0f5fc6cbafa3e7c84f258d1865996d97ae67a318.gh.tar.gz 609698 BLAKE2B db34b8a3157b78340f75fc07d8c2dc333610d962c3849fce3906e643159904ef28cb94fed062c4607a114f9de3bfa822706c2ea6a5eef5833d17e25690c83603 SHA512 692092451376be2424faf395bbdc4f61bec91f6807a0f04d1c701fc2767a4c844830f93b01cf5a813febf9d267a52d968f4f5f8b983eb7cc5ffcb91cc716739a

dev-python/trio/trio-0.25.1_p20240613.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+EGIT_COMMIT=0f5fc6cbafa3e7c84f258d1865996d97ae67a318
+MY_P=${PN}-${EGIT_COMMIT}
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/${EGIT_COMMIT}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-23.2.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.2.1[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# Bug https://bugs.gentoo.org/916756
+# distutils_enable_sphinx docs/source \
+# 	dev-python/immutables \
+# 	dev-python/sphinxcontrib-trio \
+# 	dev-python/sphinx-rtd-theme \
+# 	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+		# requires ruff
+		_tests/tools/test_gen_exports.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	rm -rf trio || die
+	epytest -p trio._tests.pytest_plugin \
+		-m "not redistributors_should_skip" \
+		--pyargs trio \
+		--skip-optional-imports
+}