media-radio/tucnak: add 4.42

Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

media-radio/tucnak/Manifest

@@ -1,2 +1,3 @@
 DIST tucnak-4.39.tar.gz 3603142 BLAKE2B 21d7e90f7e84628550e8db8bf270fcc31df2d09490ece7625b34c06c01c7672c841b08e8146754af470c1fc26d612ebefb3cf30dec4a32458cbfc173e6ffc9db SHA512 950d2014579287f3e9a0ea34e2e25ae169170ba8469a48eb2b49b38bf6d5e7246fa6a01f43531d8faa5f3577bbf62181eaa5eb6f11c244e309ee6e8ce2c16c66
 DIST tucnak-4.40.tar.gz 3603819 BLAKE2B 968fe3dca29989b3fac5a00a9ba5670778bb8379c08ff86af7449f1ccb498b70cc652368e57157d15a1b6ffcbcef07ad31909552b1f755376656cbc228e5c5c6 SHA512 9e709f18dd530b963a7868ded16e6f310b904a7c8d2cf8a1455377ce0a97db86da0199ed65da1e2409fe197ae55329885de87c0b1376d6967f853983810cf636
+DIST tucnak-4.42.tar.gz 3607419 BLAKE2B f9de386a40c9fbef4b73571be19aa6042ed0878cf12ea7749946590278d5f27cd6492f16d5f30b7d7e3cf04e1d91afe8cd9a9dab8361421fc9e7f2decaaead0c SHA512 a602e1853513b6a2289a616b36048afd3d5131f8d06797536a4cf227d866b11fbb4f3f6d19ae52de9f42a87b34d5169252e8c85b47e39b6aff09876379284e48

media-radio/tucnak/tucnak-4.42.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	~dev-libs/libzia-4.42
+	media-libs/libsndfile
+	media-libs/libsdl2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}