gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: add 6.54.4

Browse Source 
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Arthur Zamarin
2022-08-21 21:02:21 +03:00
parent 863e813216
commit a030f2cb18
2 changed files with 77 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -3,3 +3,4 @@ DIST hypothesis-6.53.0.gh.tar.gz 9323355 BLAKE2B 589cd4803351e72cc1896453e5e548b
DIST hypothesis-6.54.1.gh.tar.gz 9324403 BLAKE2B 897fa4901a5c5c0e32c4197020702dbe5d85a5ada79f52b66fc7f19180a32f4dce54f5300722f500fb560766e1ff76b5df648be6be0f229ece4b3aa0af856fc3 SHA512 ba4a7a3f5daa7437e903604d26a9dd0e4ce77d0a44a2e81fec5620f48a5f6a9080b5e5401fa1f7ee6c66d4e1d51cca095ce7e74999b0439b5a8a0c2d26f64464
DIST hypothesis-6.54.2.gh.tar.gz 9324746 BLAKE2B 25e3effa9667e8b6c57dff0ed00c14cc36385678475a1a1ac9fd30d2e293ea3a49d76ad34e391b33bad7214ce97b5d23aebedcb5d7f74686f3182a72e133416f SHA512 f53d589426b2340f6d747763cc4228f632474bc833e53e2d67fd6545437fc46cf976055dd0f1a55c4cb6377667ce0b0d8bc7dae33454157fbb91af7a5b009b62
DIST hypothesis-6.54.3.gh.tar.gz 9325211 BLAKE2B e0d6bc21057b50676ef98d1c9721b82c30986670758b2a7bfd1b101cc8d42258bf0d61887867445aafe13b8064c47d64583ab492e21b6fea510ef0c26fe01782 SHA512 288c5ea9c1dd8ee0839c11385f52ba8b8122f408aa11c6d2416460233ef78890e3014e659ef4312da4822da3abe2dd9163f68d2711556800e805ae41280aa132
DIST hypothesis-6.54.4.gh.tar.gz 9325437 BLAKE2B 2000c806a0c791d1eb353a829e5e96d53e935d360fd450b3807186121fec4dfd171b8821e08b6c23b0cbea8d24b0d88c32126281173a0de2f12b29d09ec2d62b SHA512 7e5b70cc2df874163205e3d35f3f5e6a71319e779b35f1596c69222373e9b766a143ccf37aa1699de6b98827978e44ccbca0b1e30e6ffe29c8b68c83bb3af869

76
dev-python/hypothesis/hypothesis-6.54.4.ebuild Normal file
View File

@@ -0,0 +1,76 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
CLI_COMPAT=( python3_{8..10} )
PYTHON_COMPAT=( "${CLI_COMPAT[@]}" python3_11 pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
TAG=hypothesis-python-${PV}
MY_P=hypothesis-${TAG}
DESCRIPTION="A library for property based testing"
HOMEPAGE="
https://github.com/HypothesisWorks/hypothesis/
https://pypi.org/project/hypothesis/
"
SRC_URI="
https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
-> ${P}.gh.tar.gz
"
S="${WORKDIR}/${MY_P}/hypothesis-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' "${CLI_COMPAT[@]}")
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
# subtests are broken by warnings from random plugins
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
}
python_install() {
distutils-r1_python_install
if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
fi
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}