dev-vcs/fossil: Bump to 2.18

Signed-off-by: Aaron W. Swenson <titanofold@gentoo.org>

dev-vcs/fossil/Manifest

@@ -1 +1,2 @@
 DIST fossil-src-2.16.tar.gz 6275775 BLAKE2B 504f828f121385ec73311b340e0abfdba7da6a8571adb390c55c75fea0ef027366fb914c12552e177988bedbb735a3148d87ebdb23ffc2ce4b7bef8ef603692a SHA512 0569640a3b509c592f812a42526eec88ead034ba0ba3de93da62cfb1caa751954ae185eaa3398d411a02ee2a858ecae6cdf4e47199847527f7524fc9798a4b12
+DIST fossil-src-2.18.tar.gz 6308652 BLAKE2B 299406d365e24c139e8bfbf94dc0aee2c04aa02a9f4c48d1425d0f6d21830aece10cbc5a38cee18cec03d3d0f39db3726d4890c09ca9bfc84a5058e76756ed4d SHA512 9dfeef1cc394af7afc6b68d2ebf084d5962698123518999130162718d450d061ab286b5f4039cde1af0e17059a9c801f1ded974fdb78b0965b73a7f8c80fd277

dev-vcs/fossil/fossil-2.18.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_TAG=84f25d7eb10c0714109d69bb2809abfa8b4b5c3d73b151a5b10df724dacd46d8
+
+DESCRIPTION="Simple, high-reliability, source control management, and more"
+HOMEPAGE="https://www.fossil-scm.org/"
+SRC_URI="https://fossil-scm.org/home/tarball/${MY_TAG}/fossil-src-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="debug fusefs json miniz system-sqlite +ssl static tcl tcl-stubs
+	  tcl-private-stubs th1-docs th1-hooks"
+
+REQUIRED_USE="ssl? ( !miniz )"
+
+RDEPEND="
+	sys-libs/zlib
+	|| (
+		sys-libs/readline:0
+		dev-libs/libedit
+	)
+	system-sqlite? ( >=dev-db/sqlite-3.38.0:3 )
+	ssl? ( dev-libs/openssl:0= )
+	tcl? ( dev-lang/tcl:0= )
+"
+
+# Either tcl or jimtcl need to be present to build Fossil (Bug #675778)
+DEPEND="${RDEPEND}
+	!tcl? (
+		|| (
+			dev-lang/tcl:*
+			dev-lang/jimtcl:*
+		)
+	)
+"
+
+# Tests can't be run from the build directory
+RESTRICT="test"
+
+# fossil-2.10-check-lib64-for-tcl.patch: Bug 690828
+PATCHES=( "${FILESDIR}"/fossil-2.10-check-lib64-for-tcl.patch )
+
+S="${WORKDIR}/fossil-src-${PV}"
+
+src_configure() {
+	# this is not an autotools situation so don't make it seem like one
+	# --with-tcl: works
+	# --without-tcl: dies
+	local myconf="--with-openssl=$(usex ssl auto none)"
+	use debug         && myconf+=' --fossil-debug'
+	use json          && myconf+=' --json'
+	use system-sqlite && myconf+=' --disable-internal-sqlite'
+	use static        && myconf+=' --static'
+	use tcl           && myconf+=' --with-tcl=1'
+	use fusefs        || myconf+=' --disable-fusefs'
+
+	local u useflags
+	useflags=( miniz tcl-stubs tcl-private-stubs th1-docs th1-hooks )
+	for u in ${useflags[@]} ; do
+		use ${u} &&  myconf+=" --with-${u}"
+	done
+
+	tc-export CC CXX
+	CC_FOR_BUILD=${CC} ./configure ${myconf} || die
+}
+
+src_install() {
+	dobin fossil
+}