gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-24 18:58:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hatchling: Bump to 1.12.2

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-01-05 08:26:48 +01:00
parent 2cdd8406a0
commit 9fb092f329
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hatchling/Manifest
View File

@@ -1,3 +1,4 @@
DIST hatch-hatchling-v1.11.1.gh.tar.gz 367624 BLAKE2B 006f9f9ab266eba7b7e489d4359a9ddb17a6e079c31e189662da8c4d090884eeae4bf108301d5c315d823e92cb813841e41211cc55618f4ee9109bccdde61e1e SHA512 7bdf5a2930950503dbe534f6ead724ed84420193ba55137600a5b98a085e94588e333bb5a14ad944746dc400522ebbea4849718686420fd6ed7de3d6e8852d8e
DIST hatch-hatchling-v1.12.0.gh.tar.gz 379902 BLAKE2B 831ab78bff6a039a1941ca171aaccbfb97d1d31c14505d3dde60ee4283b317cc80b6e6072b63fe9e69cccbf759bf4f7db6a371502451ffa5303547273e8d2341 SHA512 40c1684bcc730e809cdbda9d15494f07bead69b1b4bf9c98a1d2a84d2053bb7b104d6bcab1e72a4de66081dd839b7ccae96d877760353e3528e8676cea5d2a5c
DIST hatch-hatchling-v1.12.1.gh.tar.gz 380805 BLAKE2B da99130ac6d07517976a6e078e8a35896202e066b124ec96577cc1e57f59a2b3476623b9af15dd9e04b2d69e7219c13ad71e55c3bf02e7beee1a10bf37ee5882 SHA512 8a8cc7fa706dcbb95bf35525351dbf0e5dc61041c7e210d81479df84cd40019b727c4244cb83af93c466f676fcf1279155f470c80e63689af01efcb0f38cdb25
DIST hatch-hatchling-v1.12.2.gh.tar.gz 381872 BLAKE2B 6290daca1f2d2cd4eb9479b2f34b782881651c0106008c8876c355e5f3aa12cdbd0168765fdc04dd7870f9b88d44cc1be8d3849b2f20393bf64bebe9dbf09dd9 SHA512 74404b3b5369f6a8350cbde9675de6d9d7a72aca721714d47d8c4052c341affed1ebb4f4caae96877c2ccf2c4bab29b8323643e2a3d7de67bfe5888f3a08cdca

77
dev-python/hatchling/hatchling-1.12.2.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=standalone
PYTHON_TESTED=( pypy3 python3_{8..11} )
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
inherit distutils-r1
TAG=${P/-/-v}
MY_P=hatch-${TAG}
DESCRIPTION="Modern, extensible Python build backend"
HOMEPAGE="
https://pypi.org/project/hatchling/
https://github.com/pypa/hatch/
"
SRC_URI="
https://github.com/pypa/hatch/archive/${TAG}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}/backend
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
# deps are listed in backend/src/hatchling/ouroboros.py
RDEPEND="
>=dev-python/editables-0.3[${PYTHON_USEDEP}]
>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
"
BDEPEND="
${RDEPEND}
test? (
$(python_gen_cond_dep '
dev-python/atomicwrites[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
dev-python/httpx[${PYTHON_USEDEP}]
dev-python/platformdirs[${PYTHON_USEDEP}]
dev-python/rich[${PYTHON_USEDEP}]
dev-python/tomli-w[${PYTHON_USEDEP}]
dev-python/virtualenv[${PYTHON_USEDEP}]
' "${PYTHON_TESTED[@]}")
)
"
distutils_enable_tests pytest
python_test() {
if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
einfo "Skipping tests on ${EPYTHON}"
return
fi
local -x EPYTEST_DESELECT=(
# these run pip to install stuff
tests/backend/dep/test_core.py::test_dependency_found
tests/backend/dep/test_core.py::test_extra_met
tests/backend/dep/test_core.py::test_extra_no_dependencies
tests/backend/dep/test_core.py::test_extra_unmet
tests/backend/dep/test_core.py::test_unknown_extra
tests/backend/dep/test_core.py::test_version_unmet
)
# top-level "tests" directory contains tests both for hatch
# and hatchling
cd "${WORKDIR}/${MY_P}" || die
local -x PYTHONPATH="src:${PYTHONPATH}"
epytest tests/backend
}