dev-python/joblib: Bump to 1.4.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/joblib/Manifest

@@ -1 +1,2 @@
 DIST joblib-1.3.2.tar.gz 1987720 BLAKE2B f16235ead3ef0172a1e0dc2abad44967b029196f6c8c7a7e0c64283cac80e2b942ebfc2df5fa975bc152f574db023a9705f48b38855a11878e5c21e04cf7d831 SHA512 9b5acba1321351cf2ae548161ced18774b8b316aaf883cc8e77bf58898d1913361a3845d64f1f1f87e4e2394eafd92e0a6a8d67947db0c9a95a40e5f579baae6
+DIST joblib-1.4.0.tar.gz 2115863 BLAKE2B cd61f3523ee697382db601ebb460aa6f4cd35947978fb07473c5e2e5337713a05aee8339acee211be0076d84a00174c37623cd6010b492aee84337abc2e5e633 SHA512 5c7e5475347906cdc8575eac8d2052470408c4ed5267d59a88a9d3126fb72b977d20b24fb0983b070e2f3c101e7da000fc03231733fef62531f9aeffacc47baf

dev-python/joblib/joblib-1.4.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Tools to provide lightweight pipelining in Python"
+HOMEPAGE="
+	https://joblib.readthedocs.io/en/latest/
+	https://github.com/joblib/joblib/
+	https://pypi.org/project/joblib/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/loky[${PYTHON_USEDEP}]
+"
+# joblib is imported by setup.py so we need ${RDEPEND}
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/threadpoolctl[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# https://github.com/joblib/joblib/issues/1115
+	joblib/test/test_memory.py::test_parallel_call_cached_function_defined_in_jupyter
+	# unexpectedly pickleable?
+	joblib/test/test_hashing.py::test_hashing_pickling_error
+	# https://github.com/joblib/joblib/issu
+	joblib/test/test_parallel.py::test_main_thread_renamed_no_warning
+)
+
+python_prepare_all() {
+	# unbundle
+	rm -r joblib/externals || die
+	sed -e "/joblib.externals/d" -i pyproject.toml || die
+	find -name '*.py' -exec \
+		sed -e 's:\(joblib\)\?\.externals\.::' \
+			-e 's:from \.externals ::' \
+			-i {} + || die
+
+	distutils-r1_python_prepare_all
+}