app-portage/elogviewer: Add PyQt6-based 3.3_pre20251208 snapshot

Drop virtualx, tests passed

Bug: https://bugs.gentoo.org/965510
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

app-portage/elogviewer/Manifest

@@ -1 +1,2 @@
 DIST elogviewer-3.2.tar.gz 29046 BLAKE2B a880fde71df3c688572c33abbc163f3ac10a53c672b01b3139d02effa5e59a05f7ae1df35a4505b1a48d7a0cb6166a21b18d1d969e1eaebab03e3620298d4f38 SHA512 2503482f14e21c7b6f69ac0d6305c7c126fa3ac944b68acef7edec0c464d2e45bc2dc348f8d38033dbc276afc132d75863c737e222f66ad5ebe870b30fec2f39
+DIST elogviewer-3.3_pre20251208-dd5ac25c.tar.gz 30150 BLAKE2B 70c0301ad8166bd8254e64632dad8ee460b51f3da99e1bcee5e60803db1dd2c9b4370864d5d5d907be28ae2daf5aaa1ffa38101e3e4f2c1cdd74058470acde17 SHA512 ccbbae2093b81fd1127cd6687f1d367a2ee54afdf4559041c5943884daae19ce9d16230b4f9b54a1baaf3d8234556a10933c89adadb85f7db301ec01df41be3c

app-portage/elogviewer/elogviewer-3.3_pre20251208.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COMMIT=dd5ac25c0a35fd443ac2b044382fe574c8a457df
+DISABLE_AUTOFORMATTING=true
+PYTHON_COMPAT=( python3_{11..13} )
+inherit desktop python-single-r1 readme.gentoo-r1
+
+DESCRIPTION="Elog viewer for Gentoo"
+HOMEPAGE="https://github.com/Synss/elogviewer"
+SRC_URI="https://github.com/Synss/${PN}/archive/${COMMIT}.tar.gz -> ${P}-${COMMIT:0:8}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~riscv ~x86"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pyqt6[gui,widgets,${PYTHON_USEDEP}]
+		sys-apps/portage[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/pyfakefs[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-qt[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+DOC_CONTENTS="In order to use this software, you need to activate
+Portage's elog features.  Required is
+	PORTAGE_ELOG_SYSTEM=\"save\"
+and at least one of
+	PORTAGE_ELOG_CLASSES=\"warn error info log qa\"
+More information on the elog system can be found in
+/usr/share/portage/config/make.conf.example
+
+To operate properly this software needs the directory
+${PORT_LOGDIR:-/var/log/portage}/elog created, belonging to group portage.
+To start the software as a user, add yourself to the portage group."
+
+src_compile() {
+	rm Makefile || die
+}
+
+src_test() {
+	export PYTEST_QT_API=pyqt6
+	local -x QT_QPA_PLATFORM=offscreen
+	epytest
+}
+
+src_install() {
+	python_newscript elogviewer.py elogviewer
+
+	make_desktop_entry --eapi9 ${PN} -c System
+
+	doman elogviewer.1
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}